Построение сводной таблицы на форме с загрузкой данных из ADODB.Recordset

#CCADO
static void Job_showUserGroupInActiveXPivot(Args _args)
{
    Form                form = new Form();
    FormBuildDesign     formBuildDesign = form.addDesign('Design');
    Args                args = new Args();
    FormRun             formRun;
    FormActiveXControl  pivotTable;

    UserGroupList       userGroupList;
    UserInfo            userInfo;
    UserGroupInfo       userGroupInfo;

    COM                 rst,flds,fld;   // переменные ADO

    COM                 ptConstants;    // переменные PivotTable
    COM                 activeView;
    COM                 avFieldSets, fieldSet;
    COM                 pivotFields, pivotField, pivotTotal;
    COM                 comTemp;

    void processFieldSet(COM _axis, str _fieldSetName)
    {
        fieldSet = avFieldSets.Item(_fieldSetName);
        _axis.InsertFieldSet(fieldSet);     // добавляем FieldSet в ось (т.е в Строки или в Столбцы)

        pivotFields = fieldSet.Fields();    // в семействе полей FieldSet'а...
        pivotField = pivotFields.Item(0);   // ...находим единственное поле... (индексация начинается с 0)
        pivotField.Subtotals(1, false);     // ...и гасим (false) для него промежуточные итоги
        // по поводу 1 см. "Must be 1" в [url]http://msdn.microsoft.com/en-us/library/aa831714(office.10).aspx[/url]
    }
    ;

// готовим рекордсет
    rst = AdoRst::openRecordsetInMemory([   // метод можно взять здесь: [url]http://www.axforum.info/forums/blog.php?b=60[/url]
            ['UserId'    , #adVarChar,  5 ],
            ['UserName'  , #adVarChar, 40 ],
            ['GroupId'   , #adVarChar, 10 ],
            ['GroupName' , #adVarChar, 40]]);

    flds = rst.Fields();

    while select userGroupList
        join userInfo
            where userInfo.id == userGroupList.userId
        join userGroupInfo
            where userGroupInfo.id == userGroupList.groupId
    {
        rst.AddNew();
            fld = flds.Item('UserId'   ); fld.Value(userGroupList.userId );
            fld = flds.Item('UserName' ); fld.Value(userInfo.name        );
            fld = flds.Item('GroupId'  ); fld.Value(userGroupList.groupId);
            fld = flds.Item('GroupName'); fld.Value(userGroupInfo.name   );
        rst.Update();
    }

// динамически генерируем форму
    args.object(form);

    formRun = classFactory.formRunClass(args);
    formRun.init();
    formRun.design().caption('Сводная таблица "Пользователи-Группы"');

    pivotTable = formRun.design().addControl(FormControlType::ActiveX, 'PivotTable');
    pivotTable.className('{0002E542-0000-0000-C000-000000000046}'); // Microsoft Office PivotTable 10.0

    pivotTable.heightMode(FormHeight::ColumnHeight);    // именно heightMode ! не путать с просто height
    pivotTable.widthMode(FormWidth::ColumnWidth);       // именно widthMode  ! не путать с просто width
    pivotTable.AutoFit(false);

    ptConstants = pivotTable.Constants(); // для использования ниже именованной константы plFunctionCount

// передаем рекордсет ActiveX'у
    pivotTable.DataSource(rst);


    activeView = pivotTable.ActiveView();
    avFieldSets = activeView.FieldSets(); // список доступных полей рекордсета для размещения в сводной таблице

// сокрытие разных "визуальных раздражителей" (здесь хорошо помог \Classes\GM_PivotViewManager\ initDefaultViewProperties от GMCS)
    COM::createFromObject( pivotTable.ActiveData() ).HideDetails();     // это лучше сделать до размещения полей и особенно итогов - иначе летаргически долго
    COM::createFromObject( activeView.TitleBar()   ).Visible(false);    // выключение синего заголовка "Сводная таблица MS Office 10.0"
    comTemp = ActiveView.FilterAxis();
    COM::createFromObject( comTemp.Label() ).Visible(false);            // выключение области "Перетащите сюда поля фильтра"
    pivotTable.AllowDetails(false);                                     // чтобы убрались "+/-" и не получать надпись "Нет деталей"
    pivotTable.DisplayOfficeLogo(false);                                // выключение самой левой красно-сине-желто-зеленой кнопки на панели


// наполняем строки полями UserName и UserId
    processFieldSet(activeView.RowAxis(), 'UserName');
    processFieldSet(activeView.RowAxis(), 'UserId');

// наполняем столбцы полями GroupId и GroupName
    processFieldSet(activeView.ColumnAxis(), 'GroupId');
    processFieldSet(activeView.ColumnAxis(), 'GroupName');

// наполняем область данных итогом - подсчетом кол-ва по полю GroupName (это поле осталось в переменной pivotField после его вставки в столбцы)
    pivotTotal = activeView.AddTotal('Количество', pivotField, ptConstants.plFunctionCount());  // использование именованной константы
    COM::createFromObject( activeView.DataAxis() ).InsertTotal(pivotTotal);

    formRun.run();
    formRun.wait();
}