Расширенный запрос по дате

[Димитрий]

Пробую создать расширенный запрос по дате. Не получается.

Упростил задачу и не работает даже при таком:

Есть таблица table2 c полем date1980 - d1.

public void init()
{
    QueryBuildDataSource qbds;
    date dd1 = today()-10;
    date dd2 = today()+10;
    str rangeDate = strfmt("(d1>=%1 && d1<=%2)",dd1,dd2);
    ;

    super();

    qbds = Table2_ds.query().dataSourceNo(1);

    qbds.addRange(fieldnum(Table2,RecId)).value(rangeDate);// Не работает
    //qbds.addRange(fieldnum(Table2,d1)).value(rangeDate); // -------Не работает
    //qbds.addRange(fieldnum(Table2,d1)).value(strfmt('%1..%2',dd1,dd2));// - Работает


}

Ошибка расширенного диапазона запроса: Ожидается правая круглая скобка рядом с 13

Говорит ошибка в скобках. При просмотре qbds в отладчике работающий и неработающий вариант отличаются только тем, что в нерабочем есть дополнительная пара скобок.

Мне эти скобки нужны, т.к. вообще буду сцеплять дальше такие пары по ИЛИ. Кто-нибудь сталкивался с датами в расширенном запросе и проблемами с ними?

[raz]

а qbds.addRange(fieldnum(Table2,DateField)).value(queryRange(dd1,dd2)) - это уже не "Джим Бим"?

[Димитрий]

Делать вот такие простые - это одно. А как теперь тогда присоединить еще один туда же по ИЛИ, но по другому полю даты или по этому же, но с другим диапазоном дат?

[AndyD]

Цитата:

Сообщение от Димитрий

Делать вот такие простые - это одно. А как теперь тогда присоединить еще один туда же по ИЛИ, но по другому полю даты или по этому же, но с другим диапазоном дат?

Если по тому же полю, то можно добавлять нужные диапазоны через запятую

[Димитрий]

Цитата:

Сообщение от AndyD

Если по тому же полю, то можно добавлять нужные диапазоны через запятую

Мне надо по другому.

То есть если там еще d2 дата, то вот такое вот примерно надо:

str rangeDate = strfmt("(((d1>=%1) && (d1<=%2)) || ((d2>=%1) && (d2<=%2)))",queryValue(dd1),queryValue(dd2));

[Weez]

Попробуйте str rangeDate = strfmt("((d1>=%1) && (d1<=%2))",dd1,dd2);
т.е. каждое условие заключить в отдельные скобки, должно сработать.

[Димитрий]

Ошибка расширенного диапазона запроса: Ожидается правая круглая скобка рядом с 14

[Димитрий]

Цитата:

Сообщение от Weez

т.е. каждое условие заключить в отдельные скобки, должно сработать.

Работает пока у меня только в одном случае, если записать вот так:

str rangeDate =  strfmt("d1>=%1 && d1<=%2",dd1,dd2);

но мне нужны скобки.

[lev]

уже обсуждалось...
вот рабочий вариант:

добавление уловия OR (ИЛИ) в QUERY, кавычки и скобки ОБЯЗАТЕЛЬНО!!!:

sQuery = strFmt('((%1 == "%3") || (%2 == "%3"))', fieldStr(Table, Field),
                                                  fieldStr(Table, Field),
                                                  queryValue());

[Weez]

Да, вместо dd1 и dd2 подставляйте date2strxpp(dd1) и date2strxpp(dd2)

[Димитрий]

Цитата:

Сообщение от Weez

Да, вместо dd1 и dd2 подставляйте date2strxpp(dd1) и date2strxpp(dd2)

Не работает

[lev]

конкретно для вашего примера:

str rangeDate = strfmt('((d1>="%1") && (d1<="%2"))',dd1,dd2);

[Димитрий]

Цитата:

Сообщение от lev

конкретно для вашего примера:

str rangeDate = strfmt('((d1>="%1") && (d1<="%2"))',dd1,dd2);

Не работает. Код выполняется, вот только в итоге ни одной записи из диапазона.

Axapta 3.

[lev]

Цитата:

Сообщение от Димитрий

Не работает. Код выполняется, вот только в итоге ни одной записи из диапазона.

Axapta 3.

Проверяйте правильность указанных параметров. У меня такой вариант работает стабильно и правильно.

Если уверены что все правильно указано и должны выводиться записи, выложите здесь конкретный пример с вашим кодом, так как он у вас написан.

Тоже Axapta 3.

[Димитрий]

Цитата:

Сообщение от lev

Проверяйте правильность указанных параметров. У меня такой вариант работает стабильно и правильно.

Если уверены что все правильно указано и должны выводиться записи, выложите здесь конкретный пример с вашим кодом, так как он у вас написан.

Тоже Axapta 3.

Как вы и писали, конкретно для моего случая, код вот такой вот, на Init формы:

public void init()
{
    QueryBuildDataSource qbds;
    date dd1 = today()-10;
    date dd2 = today()+10;
    str rangeDate = strfmt('((d1>="%1") && (d1<="%2"))',dd1,dd2);
     ;

    super();
    qbds = Table2_ds.query().dataSourceNo(1);

    qbds.addRange(fieldnum(Table2,d1)).value(rangeDate);

}

Данные, есть, при обычном запросе они выдаются. При предложенно мже возвращается пустой набор. У вас точно выдаются данные, или вы так думаете, что они должны выдаваться?

[lev]

Цитата:

Сообщение от Димитрий

При предложенно мже возвращается пустой набор. У вас точно выдаются данные, или вы так думаете, что они должны выдаваться?

Я же написал, что все работает стабильно! Все нормально выводится! Сейчас тоже у себя попробую написать джоб для примера.

[Weez]

Не поленился, написал джоб для проверки работоспособности - все работает, данные попадают

static void testQuery(Args _args)
{
    Query                   query;
    QueryRun                queryRun;
    QueryBuildDataSource    qbds;
    QueryBuildRange         qbr;
    EmplTable               emplTable;
    ;
    query = new Query();
    qbds = query.addDataSource(TableNum(EmplTable));
    qbr = qbds.addRange(fieldNum(EmplTable, EmplId));
    qbr.value(strfmt("((CreatedDate >= %1) && (CreatedDate <= %2))", date2strxpp(31\12\2009), date2strxpp(31\01\2010)));
    queryRun = new QueryRun(query);
    while(queryRun.next())
    {
        emplTable = queryRun.get(TableNum(EmplTable));
        info(emplTable.EmplId);
    }
}

[Димитрий]

Цитата:

Сообщение от Weez

Не поленился, написал джоб для проверки работоспособности - все работает, данные попадают

Ага. Вот так заработало

str rangeDate = strfmt('((d1>=%1) && (d1<=%2))',date2strxpp(dd1),date2strxpp(dd2));

А так глючило:

str rangeDate = strfmt('(d1>=%1 && d1<=%2)',date2strxpp(dd1),date2strxpp(dd2));

Сейчас попробую связку по ИЛИ.

[Димитрий]

Сработало и по ИЛИ. Спасибо.

[AndyD]

Для проверки расширенных диапазонов не надо писать джобов.
Достаточно открыть любую форму с датами и в запросе прописать нужное условие.

К примеру, у меня прекрасно фильтруется по такому запросу в складских журналах по полю "Идентификатор записи"

((transdate >= 01\01\2010) && (transdate <=01\01\2010)) || ((createddate >= 01\01\2010) && (createddate <=01\01\2010))