QueryRun и два Join'а

[Roman N. Krivov]

Доброго времени суток!

Столкнулся со следующей проблемой: QueryRun не понимает два join к одному datasource.

Есть запрос:

 select * from SalesTable
join CustTable on CustTable.AccountNum == SalesTable.CustAccount
join SalesLine on SalesLine.SalesId == SalesTable.SalesId
where SalesTable.SalesStatus == SalesStatus::Backorder &&
SalesLine.InventQtyReserve <> 0

Нужно такой же запрос организовать в QueryRun. Вот что я делаю:

    #define.RecId('RecId')
    Query                   query = new Query();

    QueryBuildDataSource    qbdsSalesTable;
    QueryBuildDataSource    qbdsCustTable;
    QueryBuildDataSource    qbdsSalesLine;
    ;

    qbdsSalesTable = SysQuery::findOrCreateDatasource(query, tablenum(SalesTable));
    qbdsCustTable = SysQuery::findOrCreateDatasource(query, tablenum(CustTable), tablenum(SalesTable), false);
    qbdsSalesLine = SysQuery::findOrCreateDatasource(query, tablenum(SalesLine), tablenum(SalesTable), false);

    qbdsCustTable.addLink(fieldnum(SalesTable, CustAccount), fieldnum(CustTable, AccountNum));

    qbdsSalesLine.joinMode(JoinMode::ExistsJoin);
    qbdsSalesLine.fields().dynamic(boolean::false);
    qbdsSalesLine.fields().clearFieldList();
    qbdsSalesLine.addSelectionField(fieldname2id(qbdsSalesLine.table(), #RecId));

    SysQuery::findOrCreateRange(qbdsSalesLine, fieldnum(SalesLine, InventQtyReserv)).value(SysQuery::valueNot(0));

    qbdsSalesLine.addLink(fieldnum(SalesTable, SalesId), fieldnum(SalesLine, SalesId));

    SysQuery::findOrCreateRange(qbdsSalesTable, fieldnum(SalesTable, SalesStatus)).value(SysQuery::value(SalesStatus::Backorder));

    SysQuery::findOrCreateRange(qbdsSalesTable, fieldnum(SalesTable, TotalAmountCurReserve)).value('> 0');

    queryRun = new QueryRun(query);

В результате qbdsSalesTable оказывается вообще без join'ов. Как это можно вылечить?

Microsoft Businness Solutions-Axapta 3.0 Build #1951.3730/514-193 SP3/OP023-71

[mazzy]

1.
Понимает. Отлично понимает "два join".

Цитата:

Сообщение от Roman N. Krivov

Вот что я делаю:
....
Как это можно вылечить?

Неправильно делаете.
Уж сколько раз твердилось: перестаньте программировать запросы с нуля.
накидайте в AOT, а в коде используйте
myQuery = new Query(querystr(myAOTQuery));

если честно, то по-моему, в коде полная фигня написана.
но разбираться ни сил, ни желания.

Поэтому совет: прежде чем жаловаться "не понимает", сначала проверьте по AOT.

2.
не понимает "два exists join".
об этом писалось на форуме. неоднократно. и способы решения приводились. ищите.

вкратце: не используйте exists join без необходимости. не надо с его помощью эмулировать left join.

3.
в аксапте есть режим кэширования. разберитесь с ним. ОБЯЗАТЕЛЬНО!
из-за кэширования зачастую лучше писать не один суперзапрос, а простой запрос и несколько вложенных.

Кроме того, помните о том, что Аксапта очень активно использует кэширование планов запросов на SQL.
Поэтому лучше писать простые и единообразные запросы.

В частности у вас, скорее всего, возможно лучше написать код, работающий по следующей схеме:

while select salesTable
    join salesLine
    where salesLine.SalesId == salesTable.SalesId
{
    ...
    CustTable = CustTable::find(...);
    ...
}

4. (опционально)
здесь неоднократно говорилось о влиянии порядка условий в запросе на производительность.
некоторые считают это мифом.
некоторые, как я, считают порядок условий - важной вещью.

я бы поредомендовал все-таки во всем коде придерживаться единого порядка в условиях.
условие сначала по CustTable, потом по SalesID, потом по InventQtyReserv... это что-то уникальное, наверняка, нигде не закэшированное. мало того, этот уникальный запрос может выкинуть из кэша что-нибудь нужное и достаточно часто используемое.

пишите единообразно.

5. (возможная причина ошибки)
Кроме того, условие ">0" в критериях записывается по другому "0..".

===============
В общем, сначала набросайте запрос мышкой в AOT.
Проверьте.
Уж потом, если захочется, ваяйте ваш код по созданию запроса и по закату солнца вручную.

[Roman N. Krivov]

Цитата:

если честно, то по-моему, в коде полная фигня написана.
но разбираться ни сил, ни желания.

Плохо когда не пытаются разобраться.

Задание:
Нужно выбрать все открытые заказы у которых существует хотя бы одна строка с зарезервированным количеством != 0 И чтобы не делать каждый раз CustTable::Find() нужно при'join'ить CustTable

Цитата:

не понимает "два exists join".

Тут не "два exists join", а "inner join + exists join"

Цитата:

вкратце: не используйте exists join без необходимости. не надо с его помощью эмулировать left join.

А никто и не пытается эмулировать? Да и зачем, если left join и так хорошо работает?

Цитата:

здесь неоднократно говорилось о влиянии порядка условий в запросе на производительность.

В данном случае от перестановки условий запроса скорость не измениться

Но вам скорее всего нужно писать "!0"

Согласен, хотя зарезервированное кол-во всегда больше 0. Но во избежании проблем в будущем - исправил

Цитата:

В общем, сначала набросайте запрос мышкой в AOT.
Проверьте.
Уж потом, если захочется, ваяйте ваш код по созданию запроса и по закату солнца вручную.

Я "накидал" запрос в AOT'е и в результате получил:

SELECT * FROM SalesTable WHERE ((SalesStatus = Открыто))

В общем, не понимает он два join к одному datasource, как бы вы не старались

[lev]

Цитата:

Сообщение от Roman N. Krivov

В общем, не понимает он два join к одному datasource, как бы вы не старались

Вам выше написали, используйте QueryFetchMode::One2One

т.е.:

qbdsSalesTable = SysQuery::findOrCreateDatasource(query, tablenum(SalesTable));
qbdsSalesTable.fetchMode(QueryFetchMode::One2One);
    qbdsCustTable = SysQuery::findOrCreateDatasource(query, tablenum(CustTable), tablenum(SalesTable), false);
qbdsCustTable.fetchMode(QueryFetchMode::One2One);
    qbdsSalesLine = SysQuery::findOrCreateDatasource(query, tablenum(SalesLine), tablenum(SalesTable), false);
qbdsSalesLine.fetchMode(QueryFetchMode::One2One);

[Roman N. Krivov]

Цитата:

Сообщение от lev

Вам выше написали, используйте QueryFetchMode::One2One

Просто не сразу заметил. Браузер не обновил страницу. Пришлось перезаходить.
Вариант c QueryFetchMode::One2One работает

[mazzy]

Цитата:

Сообщение от Roman N. Krivov

Плохо когда не пытаются разобраться.

угу. не бывает плохих вопросов, бывают плохие ответы

Цитата:

Сообщение от Roman N. Krivov

И чтобы не делать каждый раз CustTable::Find() нужно при'join'ить CustTable

А это то зачем?
но если уж так хочется при'join'ить, то (см. ниже)

Цитата:

Сообщение от Roman N. Krivov

Я "накидал" запрос в AOT'е и в результате получил:

SELECT * FROM SalesTable WHERE ((SalesStatus = Открыто))

В общем, не понимает он два join к одному datasource, как бы вы не старались

а у меня получается. нисколько не старался.

[tricky]

Да, эта проблема в тройке давно известна. Попробуйте перестроить запрос примерно так:
SalesLine --> SalesTable --> CustTable

[mazzy]

Цитата:

Сообщение от tricky

Да, эта проблема в тройке давно известна. Попробуйте перестроить запрос примерно так:
SalesLine --> SalesTable --> CustTable

о_О!

[tricky]

... ну, или попробовать fetchMode(1:1)

[ddadream]

вон tricky советует, попробуйте и отпишитесь... я о такой проблеме не в курсе, возможно он дело говорит.

К тому же датасорцев там ТРИ, а не один. На каждую таблицу по одному

[lev]

вот джобик для ясности (возможно будет понятней):

Query                   query = new Query();
    QueryBuildDataSource    qbds1, qbds2, qbds3;
    ;

    qbds1 = query.addDataSource(tableNum(SalesTable));
    qbds1.fetchMode(QueryFetchMode::One2One);
    qbds2 = qbds1.addDataSource(tableNum(CustTable));
    qbds2.fetchMode(QueryFetchMode::One2One);
    qbds3 = qbds2.addDataSource(tableNum(SalesLine));
    qbds3.fetchMode(QueryFetchMode::One2One);

    qbds1.addRange(fieldNum(SalesTable, SalesId)).value(SysQuery::valueNotEmptyString());
    qbds2.addRange(fieldNum(CustTable, AccountNum)).value(QueryValue('Тест'));
    qbds3.addRange(fieldNum(SalesLine, ItemId)).value(QueryValue('Товар'));

    info(qbds1.toString());

[Roman N. Krivov]

Цитата:

Сообщение от lev

вот джобик для ясности (возможно будет понятней):

Query                   query = new Query();
    QueryBuildDataSource    qbds1, qbds2, qbds3;
    ;

    qbds1 = query.addDataSource(tableNum(SalesTable));
    qbds1.fetchMode(QueryFetchMode::One2One);
    qbds2 = qbds1.addDataSource(tableNum(CustTable));
    qbds2.fetchMode(QueryFetchMode::One2One);
    qbds3 = qbds2.addDataSource(tableNum(SalesLine));
    qbds3.fetchMode(QueryFetchMode::One2One);

    qbds1.addRange(fieldNum(SalesTable, SalesId)).value(SysQuery::valueNotEmptyString());
    qbds2.addRange(fieldNum(CustTable, AccountNum)).value(QueryValue('Тест'));
    qbds3.addRange(fieldNum(SalesLine, ItemId)).value(QueryValue('Товар'));

    info(qbds1.toString());

Такой вариант работает. Благодарю за помощь

[mazzy]

хотя...
кашперук советует всегда 1:1 Связывание источников данных в запросах

[ddadream]

может быть как то так:

static void Job2(Args _args)
{
    Query                   query;
    QueryRun                queryRun;
    QueryBuildDataSource    qbdsSalesTable;
    QueryBuildDataSource    qbdsCustTable;
    QueryBuildDataSource    qbdsSalesLine;

    QueryBuildRange           queryBuildRange;
    QueryBuildLink            queryBuildLink, queryBuildLink1;
    salestable  salestable;
    ;


    query = new Query();

    qbdsSalesTable = query.addDataSource(tablenum(SalesTable));

    queryBuildRange = qbdsSalesTable.addRange(fieldnum(SalesTable, SalesStatus));
    queryBuildRange.value( queryvalue(salesstatus::Backorder) );

    qbdsCustTable =  qbdsSalesTable.addDataSource(tablenum(CustTable));
    qbdsSalesLine =  qbdsSalesTable.addDataSource(tablenum(SalesLine));

    //qbdsCustTable.joinMode( 2 );
    //qbdsSalesLine.joinMode( 2 );
    
    qbdsSalesLine.fetchMode( QueryFetchMode::One2One );
    qbdsCustTable.fetchMode( QueryFetchMode::One2One );


    queryBuildLink = qbdsSalesLine.addLink(fieldnum(SalesTable, salesid),fieldnum(salesline, salesid));
    queryBuildLink1 = qbdsCustTable.addLink(fieldnum(SalesTable, custaccount),fieldnum(custtable, accountnum));

    queryRun = new QueryRun(query);


    while (queryRun.next())
    {
        salestable = queryRun.get(tablenum(Salestable));
        
        info (strfmt("salesid %1 - %2", salestable.salesid, salestable.RecId));
    }

}

[mazzy]

похоже первым ответ дал Dron aka Andy в далеком 2005 году
Join трех таблиц (две к одной)

[oip]

Похоже, первыми были наши далекие предки.

Вопрос знатокам QBE и Query в AXAPTA
Древовидная структура источников данных в Query