Программная разноска накладной для заказа на покупку на основе отборочной накладной.

[alexkrut]

Использую метод PurchFormLetter.update(). Отборочная накладная разносится без проблем, а вот обычная в упор не видит ранее созданную отборочную при выборе PurchUpdate::PackingSlip. Есть предположение, что в update() нужно передать packedTmpFrmVirtualList. Кто-нибудь сталкивался с подобным? Буду благодарен за помощь.

[Sada]

http://axforum.info/forums/search.php?searchid=245371
не то?

[alexkrut]

Цитата:

Сообщение от Sada

http://axforum.info/forums/search.php?searchid=245371
не то?

Ознакомился. не то.

[Sada]

static void autoCreateInvoice(PurchTable _purchTable, PurchUpdate _purchUpdate, InvoiceDate _invoiceDate = systemDateGet(), boolean _storno = false, InvoiceId  _invoiceId = "")
{
    PurchFormLetter_Invoice     purchFormLetter;
    PurchParmUpdate             purchParmUpdate;
    ;
    purchFormLetter = purchFormLetter::construct(DocumentStatus::Invoice);
    purchFormLetter.createParmUpdate();
    purchParmUpdate = purchFormLetter.purchParmUpdate();
    purchParmUpdate.selectForUpdate(true);
    purchParmUpdate.Storno = _storno;
    purchParmUpdate.doUpdate();
    purchFormLetter.purchParmUpdate(purchParmUpdate);
    purchFormLetter.parmCallerTable(_purchTable);
    purchFormLetter.initParmPurchTable(_purchTable);
    purchFormLetter.specQty(_purchUpdate);
    purchFormLetter.transDate(_invoiceDate);
    if (_invoiceId)
        purchFormLetter.parmParmTableNum(_invoiceId);
    purchFormLetter.initLinesQuery();
    purchFormLetter.run();
}

если суда PurchUpdate::PackingSlip интересно заработает или нет)

[alexkrut]

Цитата:

Сообщение от Sada

static void autoCreateInvoice(PurchTable _purchTable, PurchUpdate _purchUpdate, InvoiceDate _invoiceDate = systemDateGet(), boolean _storno = false, InvoiceId  _invoiceId = "")
{
    PurchFormLetter_Invoice     purchFormLetter;
    PurchParmUpdate             purchParmUpdate;
    ;
    purchFormLetter = purchFormLetter::construct(DocumentStatus::Invoice);
    purchFormLetter.createParmUpdate();
    purchParmUpdate = purchFormLetter.purchParmUpdate();
    purchParmUpdate.selectForUpdate(true);
    purchParmUpdate.Storno = _storno;
    purchParmUpdate.doUpdate();
    purchFormLetter.purchParmUpdate(purchParmUpdate);
    purchFormLetter.parmCallerTable(_purchTable);
    purchFormLetter.initParmPurchTable(_purchTable);
    purchFormLetter.specQty(_purchUpdate);
    purchFormLetter.transDate(_invoiceDate);
    if (_invoiceId)
        purchFormLetter.parmParmTableNum(_invoiceId);
    purchFormLetter.initLinesQuery();
    purchFormLetter.run();
}

если суда PurchUpdate::PackingSlip интересно заработает или нет)

а у вас какая версия аксапты?

[Sada]

2009, на что то ругается?

[alexkrut]

Цитата:

Сообщение от Sada

2009, на что то ругается?

нет, но проблема осталась. не видит отборочную накладную.

[alexkrut]

На всякий случай уточню, при PurchUpdate::All накладные успешно создаются.

[Sada]

ну это работающий код)))что значит не видит отборочную накладную? хотя, если вы говорите что не работает, то не работающий)))))

[EVGL]

Можно попытаться пойти по пути наименьшего сопротивления и в одно польское поле в PurchParmTable прописать напрямую номер накладной. Кроме того, рекомендуется RU8, в котором исправлена ошибка русского GLS при выборе отборочной накладной.

[alexkrut]

Цитата:

Сообщение от EVGL

Можно попытаться пойти по пути наименьшего сопротивления и в одно польское поле в PurchParmTable прописать напрямую номер накладной. Кроме того, рекомендуется RU8, в котором исправлена ошибка русского GLS при выборе отборочной накладной.

Путь наименьшего сопротивления не подходит, так как не создается запись в PurchParmTable.

[alexkrut]

Так же удалось выяснить, что если руками проставить в форме PurchJournalSelect_PackingSlip галочку в поле "Включить" у нужной отборочной накладной, то разноска проходит нормально. Может кто-то знает как это сделать программным способом?

[SRF]

Не знаю что у вас не работает, но у меня прекрасно работает код а-ля (DAX 2009 RU8)

    purchFormLetter = purchFormLetter::construct(DocumentStatus::Invoice);
    purchFormLetter.update(purchTable,
                           purchTable.PurchId,
                           systemDateGet(),
                           PurchUpdate::PackingSlip);

Если нужно разнести определенную отборочную накладную, используйте параметр _packedTmpFrmVirtualList - пример использования можно найти по перекрестным ссылкам.

static void CreateInvoiceByPackingSlipJour(Args _args)
{
    PurchFormLetter         purchFormLetter;
    PurchTable              purchTable                  = PurchTable::find(...);
    RefRecId                refRecIdPackingSlipJourId   = ...;

    TmpFrmVirtual           tmpFrmVirtual;
    VendPackingSlipJour     vendPackingSlipJour = VendPackingSlipJour::findRecId(refRecIdPackingSlipJourId);

    List                    listRecord  = new List(Types::Record);
    ;

    tmpFrmVirtual.clear();
    tmpFrmVirtual.CompanyId = vendPackingSlipJour.DataAreaId;
    tmpFrmVirtual.TableNum  = vendPackingSlipJour.TableId;
    tmpFrmVirtual.RecordNo  = vendPackingSlipJour.RecId;
    tmpFrmVirtual.NoYes     = NoYes::Yes;
    tmpFrmVirtual.Id        = vendPackingSlipJour.PurchId;
    tmpFrmVirtual.insert();

    listRecord.addEnd(tmpFrmVirtual);

    purchFormLetter = purchFormLetter::construct(DocumentStatus::Invoice);
    purchFormLetter.reArrangeNow(false);
    purchFormLetter.update(purchTable,
                           purchTable.PurchId,
                           systemDateGet(),
                           PurchUpdate::PackingSlip,
                           AccountOrder::None,
                           purchFormLetter.proforma(),
                           purchFormLetter.printFormLetter(),
                           purchFormLetter.usePrintManagement(),
                           purchFormLetter.creditRemaining(),
                           listRecord.pack());

    info("done");
}

Правда у меня SQL стал чертыхаться на метод PurchFormLetter_Invoice\selectFromJournal в месте

tmpFrmVirtual.RecordNo == vendPackingSlipJour.RecId &&
tmpFrmVirtual.TableNum == vendPackingSlipJour.TableId

пришлось заменить на конструкцию вида

    while select tmpFrmVirtual
        order by Id
        where tmpFrmVirtual.TableNum   == tableIdPackingSlip
        join vendPackingSlipJour
            where
            tmpFrmVirtual.RecordNo == vendPackingSlipJour.RecId

[alexkrut]

Спасибо! Помогло формирование _packedTmpFrmVirtualList. Правда теперь появляется сообщение о том, что не заполнено поле "ссылка на строку", но это наверное из-за неправильного формирования отборочной накладной.

[plumbum]

Есть еще метод purchFormLetter.chooseLinesQuery(), через который можно вообще любой запрос
на разноску повесить, только разноску надо потом вызыват методом run()

[alexkrut]

Цитата:

Сообщение от plumbum

Есть еще метод purchFormLetter.chooseLinesQuery(), через который можно вообще любой запрос
на разноску повесить, только разноску надо потом вызыват методом run()

А можно по-подробнее про это?

[Romb]

Добрый день. Почему не делаете для разноски отборочной накладной

purchFormLetter = purchFormLetter::construct(DocumentStatus::PackingSlip)?