Получение данных с диалога

[syl]

Создал такой диалог:

class DialogCommRate extends RunBase
{
    DialogField             dialogField;
    DialogField             dialogRate;
    DialogButton            dialogButton;
    TradeCurencyConversion  tcc;
    BankGroupId             bgi;

    #define.CurrentVersion(1)
    #localmacro.CurrentList
        tcc,
        bgi
    #endmacro
}

public Object dialog()
{
    DialogRunbase      dlg;
    ;
    dlg = super(dlg);
    dlg.caption("@SYS54755");
    dialogField = dlg.addField(typeid(TradeCurencyConversion));
    dialogRate = dlg.addFieldValue(typeid(BankGroupId), bgi, "Коммерческий курс", "Коммерческий курс");
    dialogRate.visible(false);
    return dlg;
}

public void dialogPostRun(DialogRunbase dialog)
{
    ;
    Super(dialog);
    dialog.formRun().controlMethodOverload(true);
    dialog.formRun().controlMethodOverloadObject(this);
}

protected boolean fld1_1_selectionChange()
{
    ;
    dialogRate.visible(dialogField.value() == 2);
    dialogRate.value(bgi);
    return true;
}

public container pack()
{
    return [#CurrentVersion, #CurrentList];
}

public boolean unpack(container packedClass)
{
    Version version = RunBase::getVersion(packedClass);
    ;
    switch (version)
    {
        case #CurrentVersion:
            [version, #CurrentList] = packedClass;
            break;
        default:
            return false;
    }
    return true;
}

public boolean getFromDialog()
{
;
    tcc = dialogField.value();
    bgi = dialogRate.value();

    return true;
}

static void myJob(Args _args)
{
    DialogCommRate d = new DialogCommRate();
    d.prompt();
    //тут ему надо задать начальное значение и получить обратно
}

Подскажите как получить из него значения dialogField и dialogRate после нажатия кнопки ОК?

Так же у меня не выходит передать ему начальное значение dialogRate, создавал метод parm но он не работает.

[mazzy]

основная военная хитрость состоит в том, чтобы dialogField* создавать вне диалога, а не внутри его. тогда переменные dialogField* и будут вашими ручками, за которые можно дергать за вымя содержимое диалога.

см. класс tutorialRunBaseBatch.
в частности методы dialog и getFromDialog

[mazzy]

что касается вашего класса и вашего вопроса, то диалог тут вообще не причем.

у вас есть класс.
внутри класса приватные переменные.
вы хотите получить доступ к приватным переменным извне класса.

создавайте parm-методы (в Аксапте они заменяют традиционные геттеры и сеттеры).

[pedrozzz]

Цитата:

Сообщение от syl

Подскажите как получить из него значения dialogField и dialogRate после нажатия кнопки ОК?

Значения вы получаете в методе getFromDialog, дальше уже работаете с переменными.

Цитата:

Сообщение от syl

Так же у меня не выходит передать ему начальное значение dialogRate, создавал метод parm но он не работает.

static void myJob(Args _args)
{
    DialogCommRate d = new DialogCommRate();
    
    d.getLast();
    d.parmBgi('test')
    
    if (d.prompt())
    {
        info(d.parmBgi());
    }
}

Вообще посмотрите классы Tutorial_RunbaseBatch и Tutorial_RunbaseForm + какую-нибудь книжку по аксапте, например Еременко/Шашков по версии 3.0

[syl]

Я понимаю что подход в целом не правильный. Но задача в данном случае стоит именно такая.

Мне не разрешают изменять логику которая уже реализована, если передавать значения по ссылке то нету возможности управлять видимостью поля dialogRate в зависимости от значения dialogField. А если делать нормальную обработку в методе Run, то мне придется переписать текущую логику, что мне делать запретили ))

[Владимир Максимов]

Хм... Ну, если намеки не понимаете, то надо делать так.

1. Создаете в своем классе 2 дополнительных метода

TradeCurencyConversion parmTcc(TradeCurencyConversion _tcc  = tcc)
{
;
    tcc = _tcc;

    return tcc;
}


BankGroupId parmBgi(BankGroupId _bgi  = bgi)
{
;
    bgi = _bgi;

    return bgi;
}

2. Вызов класса

static void myJob(Args _args)
{
    DialogCommRate d = new DialogCommRate();
    
    // Если переменная, для которой надо задать начальное значение включена в макрос #CurrentList, 
    // или формируется в методе unpack, то предварительно надо достать сохраненные значения
    d.getLast();  

    // Собственно передача начального значения ПОСЛЕ вызова getlast()
    d.parmBgi('test')
    
    if (d.prompt())
    {
        // После закрытия диалога с пользователем через нажатие Ok читаем параметры
        info(strFmt('%1',d.parmBgi()));
        info(strFmt('%1',d.parmTcc()));
    }
}