Проверить переменную на null

[PMS]

Здравствуйте!

Есть класс, в котором есть метод, который может принимать на вход переменную anytype, а может и не принимать (значение по умолчанию null).

void myMethod(anytype _var = null)
{
    ....
}

Как бы мне проверить, что переменную в метод не передавали, т.е. она равна null?

вариант:

if (_var == null)

выдаст: "Ошибка времени выполнения: Неправильные типы аргументов операции сравнения."

Из того, что смог сделать, спасло только:

if (strfmt("%1", typeof(_var)) == "")

Ничего другого в голову не приходит (видимо вечер сказывается...), а это как-то некрасиво, на мой взгляд. Может можно как-то лучше написать?


PS: Извиняйте, если уже обсуждалось. Я искал, но не нашел.

[belugin]

prmIsDefault

или попробовать if (_var) (если пустая строка тоже катит, например)

[PMS]

prmIsDefault не помог в данной ситуации, всегда возвращает 0 (вне зависимости от того, передали что-нибудь или нет).

А вот с

if (_var)

получилось!

Спасибо большое!
Почему-то изначально отверг этот вариант (пробовал, но не заработал, видимо в силу каких-то других причин). Вечер, все-таки...

[Владимир Максимов]

Как мне кажется, единственное решение именно через typeOf(). Возможно, в комбинации с prmIsDefault(). Причем, значение typeOf(null) = 44, несмотря на то, что Types имеет значения от 0 до 17.

static client void Job_test(Args _args)
{
    void test(anytype _var = null)
    {
        if (prmIsDefault(_var))
            info('default parameters');
        else
            info('not default parameters');
            
        if (_var)
            info('exist value');
        else
            info('not exists value');

        if (typeOf(_var))
            info(strFmt('exist type \"%1\" typesNum = %2', typeOf(_var), int2str(typeOf(_var))));
        else
            info('not exists type');

    }
    ;

    warning('without parameters');
    test();
    info('');
    
    warning('set null');
    test(null);
    info('');
    
    warning('set empty string');
    test('');
    info('');
    
    warning('set value');
    test(1);
    info('');

    return;
}

PS: Хотя, скорее всего, анализ значения NULL и не нужен. Обычно подобные задачи возникают когда нет достаточно ясного понимания того, что же именно надо сделать. Как правило, в процессе реализации выясняется, что все это не очень-то и нужно...

[gl00mie]

Цитата:

Сообщение от Владимир Максимов

Причем, значение typeOf(null) = 44, несмотря на то, что Types имеет значения от 0 до 17.

"Штатный" диапазон перечисления Types не мешает полям типа RecId/RefRecId/createdTransactionId/modifiedTransactionId иметь в SqlDictionary базовый тип со значением 49, а вовсе не Types::Int64 см. Программное воссоздание записей SqlDictionary для определенной таблицы

[PMS]

Владимир, спасибо большое за подробнейший ответ!
Это мне напомнило, почему вчера не заработал вариант:

if (_var)

Он не работает с пустой строкой. (голова под вечер уже плохо соображала )

Видимо, все-таки, правильная проверка:

if (typeOf(_var) == 44)

Цитата:

Сообщение от Владимир Максимов

PS: Хотя, скорее всего, анализ значения NULL и не нужен. Обычно подобные задачи возникают когда нет достаточно ясного понимания того, что же именно надо сделать. Как правило, в процессе реализации выясняется, что все это не очень-то и нужно...

Ну, тут нужно, так как дело в том, что нужно написать метод, в который может передаваться несколько параметров, а может и не передаваться (заранее это не известно):

void myMethod(anytype _var1 = null, anytype _var2 = null, anytype _var3 = null, anytype _var4 = null  ..)
{

В самом методе надо знать сколько же именно параметров было передано (это для вызова заранее неизвестного метода COM-объекта). Т.е. если я вызову метод COM объекта с 4-мя параметрами, а на вход его нужно передать максимум 1, то, сами понимаете, вылетит exception.

[S.Kuskov]

Цитата:

Сообщение от PMS

prmIsDefault не помог в данной ситуации, всегда возвращает 0 (вне зависимости от того, передали что-нибудь или нет).

Странно. У меня на AX2009 prmIsDefault сработал

static void job_test_prmIsDefault_anytype(Args _args)
{
    void myMethod(anytype _var = null)
    {
        ;

        info(int2str(prmIsDefault(_var)));
    }
    ;
    
    myMethod();
    myMethod(NULL);
    myMethod(1);
}

[PMS]

Цитата:

Сообщение от S.Kuskov

Странно. У меня на AX2009 prmIsDefault сработал

Да, это у меня на AX4.0 тоже работает. Но попробуйте передать через цепочку вызовов и это перестает работать:

static void job_test_prmIsDefault_anytype(Args _args)
{
    void myMethod2(anytype _var = null)
    {
        ;

        info(int2str(prmIsDefault(_var)));
    }
    
    void myMethod(anytype _var = null)
    {
        ;

        myMethod2(_var);
    }
    ;
    
    myMethod();
    myMethod(NULL);
    myMethod(1);
}

PS: извините, что заранее не написал, что в добавок во всему еще существует цепочка вызовов.

[belugin]

Потому, что в первый метод вы всегда передаете значение

static void job_test_prmIsDefault_anytype(Args _args)
{
    void myMethod2(anytype _var = null)
    {
        ;

        info(int2str(prmIsDefault(_var)));
    }
    
    void myMethod(anytype _var = null)
    {
        ;
        if (prmisDefault(_var))
        {
            myMethod2();
        }
        else
        {
            myMethod2(_var);
        }
    }
    ;
    
    myMethod();
    myMethod(NULL);
    myMethod(1);
}

[belugin]

Цитата:

Сообщение от PMS

Видимо, все-таки, правильная проверка:

if (typeOf(_var) == 44)

Можно не хардкодить константу

if (typeOf(_var) == typeOf(null))

[S.Kuskov]

Ещё стоит отметить, что prmisDefault это единственный способ отличить пропуск параметра от передачи параметра совпадающего со значением по умолчанию.

[PMS]

Цитата:

Сообщение от belugin

Можно не хардкодить константу

if (typeOf(_var) == typeOf(null))

Полностью с Вами согласен!
Спасибо!

[PMS]

Цитата:

Сообщение от S.Kuskov

Ещё стоит отметить, что prmisDefault это единственный способ отличить пропуск параметра от передачи параметра совпадающего со значением по умолчанию.

Да, для одного вызова именно так. Но, к сожалению, при цепочке вызовов эта информация теряется, и остается расчитывать на null.

[belugin]

Цитата:

Сообщение от PMS

Да, для одного вызова именно так. Но, к сожалению, при цепочке вызовов эта информация теряется, и остается расчитывать на null.

Ее можно передавать (см мой фикс вашего джоба), но это геморройно

[PMS]

Цитата:

Сообщение от belugin

Ее можно передавать (см мой фикс вашего джоба), но это геморройно

Да, это уже слишком ))

[dech]

Если отойти от джобов и использовать классы, то видно, что один и тот же параметр передаётся через несколько методов. Обычно из этого следует, что нужно изменить его на поле класса и инициализировать его через конструктор или set-метод. Задача сведётся к проверке anytype-переменной на значение null. Если это не ваш случай, тогда слушайте, что говорит вам belugin.

[Владимир Максимов]

Цитата:

Сообщение от PMS

Ну, тут нужно, так как дело в том, что нужно написать метод, в который может передаваться несколько параметров, а может и не передаваться (заранее это не известно):

void myMethod(anytype _var1 = null, anytype _var2 = null, anytype _var3 = null, anytype _var4 = null  ..)
{

В самом методе надо знать сколько же именно параметров было передано (это для вызова заранее неизвестного метода COM-объекта). Т.е. если я вызову метод COM объекта с 4-мя параметрами, а на вход его нужно передать максимум 1, то, сами понимаете, вылетит exception.

Задача передачи не определенного количества параметров решается через передачу одного параметра-контейнера (Container). Сколько элементов в контейнере, столько и параметров. Разные элементы одного и того же контейнера могут иметь разные типы

Можно вместо контейнера использовать объект STRUCT, если требуется знать имя параметра. Объект Struct также позволяет записывать разные типы данных в разные элементы структуры. По сути, Struct - это программная симуляция одной записи временной таблицы. Ну, или использовать 2 контейнера: Один с именами, другой со значениями.

Хотя и это все не есть "правильные" решения. Если Вы пытаетесь сделать "обвязку" методов COM-объекта, то и надо делать отдельный метод класса Axapta под каждый конкретный метод конкретного Com-объекта. Посмотрите, для примера, классы CCADO... или семейство классов SysExcel...