Используемые версии ядра

[Logger]

Цитата:

Сообщение от gl00mie

Если периодически читать, что именно исправляют в обновлениях ядра, то просто страшно становится. Это как у медиков: пациенты делятся на больных и необследованных.

Именно что так !
Я тут нагуглил список билдов с описанием чего они фиксят.
https://www.academia.edu/9837830/AX2...SP1Hotfix_List

И возникло жгучее желание поставить сборочку посвежее.

[Link]

К интересу пользователей АХ 2009. У МС открыт следующий опрос:

Цитата:

This survey is used to collect information about your existing AX2009 deployment and your upgrade plans. We will be using the results of this survey to understand our current AX2009 customers infrastructure needs. We will also be using these results to build the AX2009 compatibility roadmap.

This survey should be completed by the AX Technical leader within your organization. Time to complete this survey is approximately 5 minutes.

[Logger]

Хм.
В последнем билде 2009-й (5.0.1600.3090) похоже поломали авторазмещение контролов либо авторесайз форм.

На всех диалогах у пакетников съехали кнопки "Повторение" и "Оповещения" на закладке "Пакет".
Исключение - когда пакетник использует обычный диалог (нарисованный руками)
В итоге
Класс Tutorial_RunbaseBatch - глючит как и большинство пакетов.
а
Класс Tutorial_RunbaseForm - нормально отрисовывает.

[gl00mie]

картинка стоит тысячи слов

[Logger]

Ну вот например.
Глюк проявляется для классов :

Tutorial_RunbaseBatch
InventCostClosing
там как и в большинстве пакетников в dialog() стоит

dialog = super();

А для
Tutorial_RunbaseForm
не проявляется, потому что там в dialog() стоит

dialog = Dialog::newFormnameRunbase(formstr(tutorial_RunbaseForm),this);

[Damn]

Цитата:

Сообщение от Logger

Хм.
В последнем билде 2009-й (5.0.1600.3090) похоже поломали авторазмещение контролов либо авторесайз форм.

Это началось уже с билда 1600.2967. Диалог начинает некорректно отображать кнопки "Оповещения" и "Повторение" уже в связках "обновленный клиент - необновленный АОС", "необновленный клиент - обновленный АОС".
Ничего нельзя поделать с этим ? Обновление до этого билда теряет смысл. Я думал может хоть в 1600.3090 исправили, а выясняется что и там баг остаётся.

[Logger]

Цитата:

Сообщение от Damn

Это началось уже с билда 1600.2967. Диалог начинает некорректно отображать кнопки "Оповещения" и "Повторение" уже в связках "обновленный клиент - необновленный АОС", "необновленный клиент - обновленный АОС".
Ничего нельзя поделать с этим ? Обновление до этого билда теряет смысл. Я думал может хоть в 1600.3090 исправили, а выясняется что и там баг остаётся.

Отчего ж нельзя.
Вот так например.
\Classes\BatchInfo\dialog

void dialog(Dialog   dialog)
{
    DialogRunBase               dialogRunBase = dialog;
    Object                      curMainGrp;
    DialogGroup                 grp2Col;
    DialogGroup                 buttonGrp;
    DialogGroup                 textGrp;
    // GRD_R93295_newKernelBuildPostRU8_pkoz, Переход на новый билд ядра (5.0.1600.3090) - подготовка., pkoz, 01.12.2015 -->
    FormBuildGroupControl       GRD_FormBuildGroupControl;
    // GRD_R93295_newKernelBuildPostRU8_pkoz, Переход на новый билд ядра (5.0.1600.3090) - подготовка., pkoz, 01.12.2015 <--
    ;

    #define.batchGrp('DialogBatchGrp')

    if (! runClass.canGoBatch() || !runClass.showBatchTab())
        return;

    usesDialogClass = Dialog::isDialogClass(dialog);
    if (! usesDialogClass)
    {
        // When using "old" system, disable batch.
        batchExecute = false;
        return;
    }
    curMainGrp = dialog.mainFormGroup();


    dialogRunBase.batchDialogTabPage(dialog.addTabPage("@SYS14462"));

    grp2Col = dialog.addGroup();
    grp2Col.frameType(FormFrameType::None);
    grp2Col.columns(3);
    grp2Col.widthMode(1);

    // GRD_R93295_newKernelBuildPostRU8_pkoz, Переход на новый билд ядра (5.0.1600.3090) - подготовка., pkoz, 01.12.2015 -->
    if ( !isRunningOnServer() && grp2Col.control() )
    {
        GRD_FormBuildGroupControl = SysDictClass::as(grp2Col.control(), ClassNum(FormBuildGroupControl));

        if (GRD_FormBuildGroupControl)
        {
            /*
            info4([
                GRD_FormBuildGroupControl.widthMode(),
                strFMT("%1", GRD_FormBuildGroupControl.widthMode()),
                GRD_FormBuildGroupControl.widthValue()
                ]);
            */

            // grp2Col.widthMode(-1);

            GRD_FormBuildGroupControl.width( 600, -1 ); // прибили гвоздями размер группы, так как в билде 5.0.1600.3090 он иногда глючит (не учитывал размер кнопок - словно их не было)
            // чтобы совсем красоту навести - надо еще в классе DialogGroup (переменная grp2Col ) реализовать метод width и запомнить widthMode и ширину
        }
        //info4([classid2Name(grp2Col.control().handle())]);
    }
    // GRD_R93295_newKernelBuildPostRU8_pkoz, Переход на новый билд ядра (5.0.1600.3090) - подготовка., pkoz, 01.12.2015 <--

    dialog.addGroup("@SYS2952",grp2Col);

    fieldBatchExecute   = dialog.addFieldValue(typeid(NoYes),batchExecute,"@SYS2312", "@SYS28499");

    dialog.addGroup("@SYS68865",grp2Col);

    dialog.addGroup("@SYS5711",grp2Col);
    if(this.parmRunClass())
        caption = this.parmRunClass().caption();
    fieldCaption        = dialog.addFieldValue(typeid(BatchCaption), caption, '',
                                new DictField(tablenum(Batch), fieldnum(Batch, Caption)).help());
    fieldGroup          = dialog.addFieldValue(typeid(BatchGroupId),groupId, '',
                                new DictField(tablenum(Batch),fieldnum(Batch,GroupId)).help());
    fieldPrivate        = dialog.addFieldValue(typeid(NoYes),privateBatch,fieldpname(Batch,PrivateTask),
                                new DictField(tablenum(Batch),fieldnum(Batch,PrivateTask)).help());

    buttonGrp = dialog.addGroup('',grp2Col);
    buttonGrp.frameType(FormFrameType::None);
    buttonGrp.leftMode(3);

    dialog.addMenuItemButton(MenuItemType::Display,menuitemdisplaystr(SysRecurrenceRun),DialogMenuItemGroup::CurrentGrp);
    dialog.addMenuItemButton(MenuItemType::Display,menuitemdisplaystr(BatchAlerts), DialogMenuItemGroup::CurrentGrp);

    dialog.curFormGroup(dialog.mainFormGroup());
    textGrp = dialog.addGroup();
    textGrp.frameType(FormFrameType::Edged3DLine);
    textGrp.alignChild(false);
    textGrp.widthMode(1);
    fieldText = dialog.addText(SysRecurrenceRun::toText(this.parmBatchHeader().parmRecurrenceData()));

    dialog.mainFormGroup(curMainGrp);
    dialog.curFormGroup(curMainGrp);

}

P.S.
А в MS писать пробовали ?
Чего говорят ?

[Damn]

Цитата:

Сообщение от Logger

А в MS писать пробовали ?
Чего говорят ?

Может проще не переводить клиента и АОС на этот билд ? Есть в нём какие-то плюсы кроме минусов ? И кстати баг с кнопками в диалоговой форме единственный ?
Не хочется тратить время на переписку с микрософтом.

[Logger]

Затрудняюсь что-то советовать.
У нас он в деве и тесте крутится уже 3 месяца. Других багов пока не выявили.
На продуктив так и не ставили пока.

[Damn]

Билд 5.0.1600.3596 не пробовали ? Он сейчас вроде последний. Вдруг там исправлено это.

[Logger]

Нет.
А у вас есть описание, что в нем пофиксили ?

[Damn]

Нет. Я и скачать-то не знаю как его.

[Rik_id7251]

Дело в том что код в классе BatchInfo методе dialog корректен и его править не надо.
Проблема тут в строчке:
buttonGrp.leftMode(3);

Значение передается корректное, но функция почему-то принимает boolean.
Исправляется в классе DialogGroup методе leftMode:

//Fix -->
/*
void leftMode(boolean leftMode)
*/
void leftMode(FormLeft leftMode)
//Fix <--
{
    if (properties)
        Dialog::setProp(properties,#leftMode,leftMode);
    else
        this.formGroup().leftMode(leftMode);
}

Вместо енума FormLeft можно просто int, кому как удобнее.

[Logger]

Интересно, что поведение ядра изменилось при передаче параметров.
Раньше оно не приводило типы (и даже ошибочно написанный X++ код мог корректно срабатывать), а теперь приводит типы и код который работал раньше - теперь не работает.

Опасно, где это еще вылезет.

Для иллюстрации набросал джобик

static void Job3015(Args _args)
{
    DictEnum    dictEnum;
    anytype     a;
    
    boolean test(boolean _parm)
    {
        ;
        
        dictEnum = new DictEnum(DictEnum::value2id(_parm));
        info(strfmt("%1; %2; %3; %4",
            typeOf(_parm),
            any2int(_parm),
            DictEnum::value2id(_parm),
            dictEnum ? dictEnum.name() : '-'
            ));

        return 3;
    }
    ;
    
    a = test(3);
    dictEnum = new DictEnum(DictEnum::value2id(a));
    info(strfmt("%1; %2; %3; %4",
        typeOf(a),
        any2int(a),
        DictEnum::value2id(a),
        dictEnum ? dictEnum.name() : '-'
        ));
    info("");
}

В новом билде (как минимум после 1600.2967) джобик выведет

Цитата:

Enum; 1; 61440; boolean
Enum; 1; 0; -

первая строка соответствует преобразованию типов при передаче параметров в метод, а вторая - при возвращении результатов.

В старом билде (RU8) результат такой:

Цитата:

Enum; 3; 61440; boolean
Enum; 1; 0; -

т.е. значение не приводилось к нужному типу и баг в X++ коде не проявлялся.

P.S. Но конечно радует, что это не баг ядра как думали в начале, а всего лишь кривой X++ код.

[Logger]

А в 2012-й (build 6.3.5000.2046) джоб выдает:

Цитата:

Enum; 1; 61440; boolean
Enum; 1; 61440; boolean

т.е. опять поведение меняется, но уже при возвращении значения из метода.