Теряется фильтр из-за того, что не задан label.

[oip]

Наверняка это уже тут обсуждалось тут где-то, но, думаю, еще раз поднять это лишним не будет. Может быть когда-нибудь кому-нибудь пригодится.

Ситуация такова. Был вот такой код:

runQuery = new QueryRun(bankQueryRun.query());
debug::printDebug(runQuery.query().dataSourceNo(1).toString());
debug::printDebug(bankQueryRun.query().dataSourceNo(1).toString());

В дебагер выводилось:

Цитата:

SELECT * FROM BankAccountTrans WHERE ((TransDate<=31.03.2007)) AND ((Dimension[3] = Накладные расходы))
SELECT * FROM BankAccountTrans WHERE ((TransDate<=31.03.2007)) AND ((CancelStatus = 0)) AND ((Dimension[3] = Накладные расходы))

Т.е. терялось "CancelStatus = 0". Я долго не мог понять, "то ли это лыжи не едут, то ли я торможу". А оказалось,что причина этого в том, что у нулевого значения энума CancelStatus не была задана метка.

Спасибо AndyD и kashperuk за помощь!

PS Можно перенести в базу знаний.

[gl00mie]

Цитата:

Сообщение от oip

Наверняка это уже тут обсуждалось тут где-то, но, думаю, еще раз поднять это лишним не будет.
оказалось,что причина этого в том, что у нулевого значения энума CancelStatus не была задана метка.

Проблемы, возникающие из-за отсутствия меток у значений Enum'ов, не так давно обсуждались в теме Query.pack()

[oip]

Точно. Пропустил я ту тему почему-то. Спасибо.

[gl00mie]

Вот небольшой скрипт для поиска "проблемных" значений перечислений. У меня нашлось 418 значений в 190 перечислениях

// gl00mie, 20070503 -->
#AOT
static void AOTprintEnumValuesUnlabeled(Args _args)
{
    TreeNodeIterator    tnIterator;
    TreeNode            tnEnum;
    DictEnum            dtEnum;
    boolean             bEnumIsOk;
    str                 strValueLabel;
    int                 i;
    int                 cnProcessed = 0;
    int                 cnUnlabeled = 0;
    int                 cnEnumsNotOk= 0;
    ;
    tnIterator  = TreeNode::findNode(#BaseEnumsPath).AOTiterator();
    while(true)
    {
        tnEnum  = tnIterator.next();
        if(!tnEnum) break;
        cnProcessed++;
        dtEnum  = new DictEnum(tnEnum.applObjectId());
        if(!dtEnum)
        {
            error(strfmt(@"Failed to create DictEnum object for '%1\%2' (objectId %3)!",
                            #BaseEnumsPath, tnEnum.AOTname(), tnEnum.applObjectId()));
            continue;
        }
        bEnumIsOk = true;
        for(i=0; i<dtEnum.values(); i++)
        {
            strValueLabel = dtEnum.index2Label(i);
            if(!strValueLabel)
            {
                cnUnlabeled++;
                bEnumIsOk = false;
                warning(strfmt(@"%1::%2 (value %3)  has no label!",
                        dtEnum.name(), dtEnum.index2Symbol(i), dtEnum.index2Value(i)));
            }
        }
        if(!bEnumIsOk)
            cnEnumsNotOk++;
    }
    info(strfmt(@"%1 base enums processed, %2 unlabeled enum values found in %3 enums", cnProcessed, cnUnlabeled, cnEnumsNotOk));
}
// gl00mie, 20070503 <--

[Zan]

Предлагаю сразу заполнить каким-нибудь непреметным значением пустые Labels.
За основу взял job от gl00mie

#AOT
static void AOTprintUpdateEnumValuesUnlabeled(Args _args)
{
    TreeNodeIterator    tnIterator;
    TreeNode            tnEnum,
                        tnEmunChild;
    DictEnum            dtEnum;

    boolean             bEnumIsOk;
    str                 strValueLabel;
    int                 i;
    int                 cnProcessed = 0;
    int                 cnUnlabeled = 0;
    int                 cnEnumsNotOk= 0;

    // zan 03.05.2007 -->
    int                 conElmUpd   = 3; //Label

    str                 properties,
                        labelValueNew = '-',
                        conValue;

    container           conProperties;
    // zan 03.05.2007 <--
    ;

    tnIterator  = TreeNode::findNode(#BaseEnumsPath).AOTiterator();
    while(true)
    {
        tnEnum  = tnIterator.next();
        if(!tnEnum) break;
        cnProcessed++;
        dtEnum  = new DictEnum(tnEnum.applObjectId());
        if(!dtEnum)
        {
            error(strfmt(@"Failed to create DictEnum object for '%1\%2' (objectId %3)!",
                         #BaseEnumsPath, tnEnum.AOTname(), tnEnum.applObjectId()));
            continue;
        }
        bEnumIsOk = true;
        for(i=0; i<dtEnum.values(); i++)
        {
            strValueLabel = dtEnum.index2Label(i);
            if(!strValueLabel)
            {
                cnUnlabeled++;
                bEnumIsOk = false;
                warning(strfmt(@"%1::%2 (value %3)  has no label!", 
                               dtEnum.name(), dtEnum.index2Symbol(i), dtEnum.index2Value(i)));

                // zan 03.05.2007 -->
                if(labelValueNew)
                {
                    tnEmunChild   = tnEnum.AOTfindChild(dtEnum.index2Symbol(i));
                    properties    = tnEmunChild.AOTgetProperties();

                    conProperties = str2con(properties,'\n');
                    conValue      = conpeek(conProperties,conElmUpd);
                    conValue     += labelValueNew;
                    conProperties = conpoke(conProperties, conElmUpd, conValue);
                    properties    = con2str(conProperties,'\n');

                    tnEmunChild.AOTsetProperties(properties);
                    tnEmunChild.AOTsave();
                    tnEnum.AOTsave();

                    //info(properties);
                }
                // zan 03.05.2007 <--
            }
        }
        if(!bEnumIsOk)
            cnEnumsNotOk++;
    }
    info(strfmt(@"%1 base enums processed, %2 unlabeled enum values found in %3 enums", cnProcessed, cnUnlabeled, cnEnumsNotOk));
}
// gl00mie, 20070503 <--

[kashperuk]

Цитата:

Сообщение от Zan

Предлагаю сразу заполнить каким-нибудь непреметным значением пустые Labels.
За основу взял job от gl00mie

Думаю лучше заполнять пробелом. Тогда визуально не будет отличаться, а работать уже будет корректно.

[Zan]

Цитата:

Сообщение от kashperchuk ->
Думаю лучше заполнять пробелом. Тогда визуально не будет отличаться, а работать уже будет корректно.

На счет пробела конечно хорошо, только при его использовании тоже есть проблемы.
Нужно обязательно чем-нибудь зополнять.