Пакетное задание

[AngelDominantes]

Добрый день. Возникли трудности с пакетным заданием. AX2009. Создал пакетный класс:

class S_RemoveOldRecordsBatch extends RunBaseBatch
{
    anytype dummy;
    #define.CurrentVersion(1)
    #define.Version1(1)
    #localmacro.CurrentList
        dummy
    #endmacro
}

void DelOldRecords()
{
    S_CustVendCommon s_CustVendCommon;
    ;

    ttsbegin;
    while select forupdate s_CustVendCommon
     where  (s_CustVendCommon.NoYesCombo == NoYesCombo::Yes)
     {
        if( intvNo(Today(), s_CustVendCommon.TransDate, intvScale::YearMonth) >= 1)
        {
            s_CustVendCommon.delete();
        }
     }

    ttscommit;
}

public container pack()
{
    return connull();
}

public boolean unpack(container packedClass)
{
   return true;
}

static void main(Args _args)
{
    S_RemoveOldRecordsBatch s_RemoveOldRecordsBatch = new S_RemoveOldRecordsBatch();
    ;
    s_RemoveOldRecordsBatch.DelOldRecords();

}

Все по сути весь класс, при ручном запуске работает при пакетной обработке нет, в свойствах класса указано запускать на сервере.
Для пакетного задания выбрана пакетная группа,
Указано запускать на сервере,
Указан АОС, который является сервером пакетной обработки и выбранная группа входит в этот АОС. Ошибок в журнале нет.

[kornix]

Можете поставить точку останова в методе s_RemoveOldRecordsBatch.DelOldRecords() и запустить выполнение в пакетном режиме (т.е. после запуска задание повеситься в пакет, а потом толкните выполнение пакетной группы вручную).
Вообще у вас пустые методы pack и unpack, т.е. при распаковке класса на сервере ничего нет. Попробуйте перекрыть эти методы вот так:

public container pack()
{
    ;
    return [#CurrentVersion];
}

public boolean unpack(container packedClass)
{
    Version     version = RunBase::getVersion(packedClass);
    container   queryCon;
    ;

    switch (version)
    {
        case #CurrentVersion:
            [version] = packedClass;
            break;
        default:
            return false;
    }

    return true;
}

[Damn]

Прикольно. Я помню тоже попадал на такую подставу. В классах-наследниках RunBaseBatch нужно все действия вписывать в run(). Именно этот метод вызывается пакетным сервером.

[AngelDominantes]

Цитата:

Сообщение от Damn

Прикольно. Я помню тоже попадал на такую подставу. В классах-наследниках RunBaseBatch нужно все действия вписывать в run(). Именно этот метод вызывается пакетным сервером.

Спасибо все заработало)

[Wamr]

Аналогичный эффект получается, если в getFromDialog не вызвать super.

--------
понимаю, что не в тему, но вдруг кому понадобится

[Владимир Максимов]

Если опустить частности, то выполнение класса через пакетное задание происходит следующим образом

batchClass = classfactory.createClass(classId);
batchClass.parmInBatch(true);
batchClass.unpack(...);
batchClass.run();

Ну, а если надо с частностями, то это метод BatchRun::runJobStatic()

Как видно из общей схемы, при запуске класса из сервера пакетной обработки, переменная inBatch принимает значение true. Опираясь на этот факт можно в самом начале метода run() "вручную" запустить те методы, которые "в обычном" состоянии запускаются из main().