Как получить в query фильтр, созданный на форме пользователем? (Ax 3.0)

[Fizik]

Подскажите пожалуйста, как получить в query конструкцию фильтра, созданную пользователем на форме.
Т.е. пользователь заходит в "Карточку сотрудника", выбирает там только операторов, принятых до 01.01.2013. Форма отображает нужные записи.
Как обратиться к этому составленному запросу в коде?

[S.Kuskov]

Form, Datasource

[Fizik]

Спасибо, ds_q и ds_qr было новым. Но мне этого не хватило. Пишу на кнопку формы:

    queryRun = emplTable_qr;
    while(queryRun.next())
    {
        emplTable = queryRun.get(tablenum(emplTable));
        info(emplTable.EmplId);
        i++;
    }
    info(int2str(i));
    super();

Результат: первая запись в info не попадает. Видимо, надо как-то "сдвигать курсор" в начало.
При повторном вызове цикл не выполняется совсем. Я так понимаю, потому что qr закончен. Как начать его сначала?

[LeonDerCom]

Так он у вас и так на первой записи стоит, а вы его некстом прогнали на 2-ую позицию, то есть либо вот так:

queryRun = emplTable_qr;
emplTable = queryRun.get(tablenum(emplTable));
info(emplTable.EmplId);
i++;
while(queryRun.next())
{
emplTable = queryRun.get(tablenum(emplTable));
info(emplTable.EmplId);
i++;
}
info(int2str(i));
super();

Иначе

QueryRun      queryRun;
EmplTable     tEmplTable;
int             i;
;
queryRun = new QueryRun(EmplTable_q);
while(queryRun.next())
{
    tEmplTable = queryRun.get(tablenum(EmplTable));
    info(strFmt('%1', tEmplTable.EmplId));
    i++;
}
info(int2str(i));

[kashperuk]

Добавлю, что именно второй вариант стоит использовать, когда создается новый инстанс QueryRun на основании запроса из таблицы (там возможно лучше EmplTable_qr.query(), чтобы пользовательские фильтры тоже попали).

Вообще не очень люблю код, где итерируют запрос, который в это же время отображается на форме.
Я, конечно, оптимист, но не верю в 100% работу ядра

[Logger]

Цитата:

Сообщение от Fizik

При повторном вызове цикл не выполняется совсем. Я так понимаю, потому что qr закончен. Как начать его сначала?

QueryRun.reset();

ставлю везде на автопилоте. Всегда помогает.

[Logger]

Цитата:

Сообщение от kashperuk

Добавлю, что именно второй вариант стоит использовать, когда создается новый инстанс QueryRun на основании запроса из таблицы (там возможно лучше EmplTable_qr.query(), чтобы пользовательские фильтры тоже попали).

Там еще надо дайналинки красиво в обычные range переделать.
Для чего были соответствующие методы то ли в global то ли в sysQuery. Навскидку не помню.

[Aron]

Цитата:

Сообщение от Fizik

Результат: первая запись в info не попадает. Видимо, надо как-то "сдвигать курсор" в начало.
При повторном вызове цикл не выполняется совсем. Я так понимаю, потому что qr закончен. Как начать его сначала?

Вспомните про конструкцию do{}while().
А после прохода сдвиньте курсор на первую позицию.

[LRA]

    FormDataSource          fds;
    QueryBuildDataSource    qbds;
    ;
    fds = this.dataSource(<     >);
    query   = fds.queryRun().query();   // Запрос с учетом фильтра пользователя на форме, заданного, например, по Ctrl+F3
//или
    query   = fds.query();              // Это если без учета фильтра пользователя
    qbds = query.dataSourceNo(xx);
//модификация qbds, если нужно, например,  qbds.addRange(…);
    queryRun = New QueryRun(query);

[LRA]

Цитата:

Сообщение от Fizik

Пишу на кнопку формы:

    queryRun = emplTable_qr;
    while(queryRun.next())
    {
        emplTable = queryRun.get(tablenum(emplTable));
        info(emplTable.EmplId);
        i++;
    }
    info(int2str(i));
    super();

Результат: первая запись в info не попадает. Видимо, надо как-то "сдвигать курсор" в начало.
При повторном вызове цикл не выполняется совсем. Я так понимаю, потому что qr закончен. Как начать его сначала?

Однозначно queryRun.reset();

Но тут многое зависит и от того, что Вы собираетесь делать с queryRun. В большинстве случаев лучше создать новый queryRun = New QueryRun(query);

[Fizik]

Спасибо всем за развернутые ответы. Все получилось и уже в работе.
Могу написать, для какой цели такая задача: из 2000 сотрудников примерно 600 необходимо напечатать доп. соглашения в Word, причем однозначного критерия, кому надо, нет. Поэтому даю пользователю в форме выбрать нужную партию людей и кнопку для печати документов для них, потом след. партия по другим критериям.

[pitersky]

Можно было с другой стороны зайти - после наложения фильтра выбирать все отфильтрованные записи по Ctrl-A и печатать их. Тогда в печати надо будет просто перебрать выбранные строки датасоурса