Программное создание comboBox в Dialog

[SuperStar88]

Надо на форму Dialog добавить поле RContractCode из таблицы RContractTable.
Должен получиться такой список


Делаю так:

protected Object dialog(DialogRunbase _dialog, boolean _forceOnClient)
{;
    dialog = super(_dialog, _forceOnClient);
    dialog.caption("Задайте параметры");

    rContractCodeField = dialog.addFieldValue(TypeId(RContractCode), rContractCode);

    return dialog;
}
public void dialogPostRun(DialogRunbase _dialog)
{
    super(_dialog);

    _dialog.formRun().controlMethodOverloadObject(this);
    _dialog.formRun().controlMethodOverload(true);
}

public void rContractCodeField_lookup()
{
    FormStringControl           formStringControl;
    SysTableLookup              sysTableLookup;
    Query                               query = new Query();
    QueryBuildDataSource     qbds;
    ;

    formStringControl = dialog.formRun().controlCallingMethod();
    sysTableLookup = SysTableLookup::newParameters(tablenum(RContractTable),formStringControl);
    sysTableLookup.addLookupfield(fieldnum(RContractTable, RContractCode));

    qbds = query.addDataSource(tablenum(RContractTable));
    // Получаем нужное поле
    qbds.addSelectionField(fieldnum(RContractTable, RContractCode));
    // Используем группировку, чтобы убрать дубли
    qbds.addGroupByField(fieldnum(RContractTable, RContractCode));
    // Отображаем только для Поставщиков
    qbds.addRange(fieldnum(RContractTable, RContractPartnerType)).value(enum2str(RContractPartnerType::Vend));

    //info(query.dataSourceNo(1).toString());
    sysTableLookup.parmQuery(query);
    sysTableLookup.performFormLookup();
}

В итоге получается такое:


То есть, не получается отфильтровать нужные данные. И оно почему-то не заходит в lookup-метод

AX2009 (5.0.1500)

[Dron AKA andy]

Попробуйте так:

public void dialogPostRun(DialogRunbase _dialog)
{
    super(_dialog);

    _dialog.dialogForm().formRun().controlMethodOverloadObject(this);
    _dialog.dialogForm().formRun().controlMethodOverload(true);
}

И лукап я бы строил по таблице RContractTypes с присоединенной по exists join RcontractTable.

[Dumfag]

Пропиши в методе dialog:
rContractCodeField .registerOverrideMethod(methodStr(formStringControl, lookup), methodStr(Название класса, rContractCodeField_lookup), this);

protected Object dialog(DialogRunbase _dialog, boolean _forceOnClient)
{;
    dialog = super(_dialog, _forceOnClient);
    dialog.caption("Задайте параметры");

    rContractCodeField = dialog.addFieldValue(TypeId(RContractCode), rContractCode);
    rContractCodeField .registerOverrideMethod(methodStr(formStringControl, lookup), methodStr(name_class_from, rContractCodeField_lookup), this);
    return dialog;
}

[dmn]

Вариант 1:

dialog.caption("Задайте параметры");

dialog.customFieldName_RU('rContractCodeField');
rContractCodeField = dialog.addFieldValue(TypeId(RContractCode), rContractCode);

Вариант 2:

public void rContractCodeField_lookup()

заменить на название поля диалога

public void Fld1_1_lookup()

[SuperStar88]

Цитата:

Сообщение от dmn

Вариант 1:

dialog.caption("Задайте параметры");

dialog.customFieldName_RU('rContractCodeField');
rContractCodeField = dialog.addFieldValue(TypeId(RContractCode), rContractCode);

Вариант 2:

public void rContractCodeField_lookup()

заменить на название поля диалога

public void Fld1_1_lookup()

Lookup заработал, благодарю Использовал 1 вариант!

Цитата:

Сообщение от Dron AKA andy

...
И лукап я бы строил по таблице RContractTypes с присоединенной по exists join RcontractTable.

Построил по таблице RContractTypes - получилось то что нужно

Цитата:

Сообщение от Dumfag

Пропиши в методе dialog:
rContractCodeField .registerOverrideMethod(methodStr(formStringControl, lookup), methodStr(Название класса, rContractCodeField_lookup), this);
...

У меня rContractCodeField это DialogField и такого метода нету

А можно в Lookup использовать SQL вместо QueryBuildDataSource и как?