Вопрос про транзакции и исключения

[Andronov]

Добрый день!
В документации написано:
1. Блоки транзакций могут быть вложенными
2. Исключение автоматически прерывает текущую транзакцию
Исходя из этого я написал такой код:

PHP код:

        CanPerform = false;
        ttsbegin;
        try {
            ttsbegin;
                select forupdate mt where mt.Name == 'ООО "Электролюкс"';
                mt.Name = 'First updated record';
                mt.update();
                if (!CanPerform)
                    throw Exception::Error;
            ttscommit;
        }
        catch (Exception::Error){
            CanPerform = true;
        }

        select forupdate mt where mt.Name == 'ООО "Мирный атом"';
        mt.Name = 'Second updated record';
        mt.update();
    ttscommit; 


Писал исключительно для примера, поэтому логику прошу не обсуждать. Имел ввиду, что транзакция в try/catch откатится и управление перейдет в catch-блок, потом оставшиеся операторы нормально выполнятся и внешняя транзакция успешно завершится. Практика показала, что в базе не происходит НИКАКИХ изменений.
Может мне кто-нибудь объяснить ход выполнения программы? Почему изменения не проходят в базу? В модели MTS/Component services используется подход, очень похожий на аксаптовский, но там подобный код будет отрабатывать именно так, как я того ожидаю.

[Wamr]

Опыт показывает, что ttsabort и exception срубают транзакции всех уровней.
Почему - не знаю, почему об этом скромно умалчивается в руководстве разработчика - тоже не знаю.

[Andronov]

Это я уже заметил.
Интересует ход выполнения программы. По идее, если после выхода из catch транзакция отменена, то select/update должны отработать вне транзакции, а если не отменена, то в рамках нее. Или как-нить сругаться, хотя бы. А на деле возникает ощущение, что после throw управление передается за последний ttscommit.

[Wamr]

Для такого кода

PHP код:

    try
    {
        ttsbegin;

        try
        {
            ttsbegin;
            select forupdate aa where aa.a == 9;
            aa.b = 1;
            aa.update();

            info("До error");
            throw Exception::error;

            info("После error");
            ttscommit;
        }
        catch (Exception::Error)
        {
            info("catch 1");
        }

        info("После catch");

        select forupdate aa where aa.a == 9;
        aa.b = 2;
        aa.update();

        ttscommit;

        info("После ttscommit");
    }
    catch (Exception::Error)
    {
        info("catch 2");
    }

    info("После всего"); 


получается следущее
До error
catch 2
После всего

Т.е. управление передается в catch, который следует за блоком try, в котором была открыта первая транзакция.

[Andronov]

Большое спасибо!
Стало яснее.