Можно ли в string-контроле с выпадающим списком настроить множественность выбора?

[Vasiliusis]

Добрый день!
Вопрос, в принципе, в заголовке. Нужно, чтобы у стрингового поля, имеющего через EDT relation с какой-либо таблицей, можно было из выпадающего списка выбирать значение и прибавлять к уже ранее выбранным через запятую/точку с запятой. К примеру, есть

CustTable - таблица контрагентов
MyCustAccount - мой EDT, связанный с CustTable.CustAccount
CustAccountControl - контрол на форме.

Вот. Нужно чтобы, в CustAccountControl содержалось что-то типа
Cust1, Cust2, Cust3

MS DAX 2009

[Murlin]

Смотря где - разные методы. На форме проще, в диалоге сложнее.
Надо lookup перекрывать и там и там и у поля ставить опр. свойства.

[andrewK]

Можно попробовать свойство ReplaceOnLookup на контроле формы установить в No.
Тогда можно добавлять выбранные значения из лукапа.

[Sada]

Меня тоже интересует, но Dialog

[raz]

Более сложный вариант, со своим лукапом.
Ваша проблема в fscInventLocationRange.replaceOnLookup(false);

public class myRunBase extends RunBase
{
    DialogRunBase           dialogRunBase;
    Range                   inventLocationRange;
    FormStringControl       fscInventLocationRange;
....
}

DialogRunbase dialog(DialogRunbase dialog, boolean forceOnClient)
{
    FormGroupControl    fgc;

    dialogRunbase = super(dialog, forceOnClient);
    fgc = dialogRunBase.curFormGroup();

    fscInventLocationRange = fgc.addControl(FormControlType::String, @"InventLocationRange");
    fscInventLocationRange.extendedDataType(extendedTypeNum(InventLocationId));
    fscInventLocationRange.text(inventLocationRange);
    fscInventLocationRange.replaceOnLookup(false);
    fscInventLocationRange.displayLength(50);
    fscInventLocationRange.limitText(250);
...
}

public void dialogPostRun(DialogRunbase _dialog)
{
    if (_dialog.formRun())
    {
        _dialog.formRun().controlMethodOverloadObject(this);
        _dialog.formRun().controlMethodOverload(true);

        fscInventLocationRange = _dialog.formRun().design().control(fscInventLocationRange.id());
    }

    super(_dialog);
}

private void InventLocationRange_lookup()
{
    SysTableLookup          sysTableLookup;
    EmplTable               emplTable = EmplTable::findByUserId_W(curuserid());

    Query                   query     = new Query();
    QueryBuildDataSource    queryBuildDataSource;
    ;
    if (!dialogRunbase)
        return;

    if (fscInventLocationRange)
    {
        sysTableLookup       = SysTableLookup::newParameters(tableNum(InventLocation), fscInventLocationRange);
        queryBuildDataSource = query.addDataSource(tableNum(InventLocation));

        if (emplTable.myInventSite)
        {
            queryBuildDataSource.addRange(fieldNum(InventLocation, InventSiteId)).value(queryValue(emplTable.myInventSite));
        }

        sysTableLookup.addLookupfield(fieldNum(InventLocation, InventLocationId));
        sysTableLookup.addLookupfield(fieldNum(InventLocation, Name));
        sysTableLookup.parmQuery(query);
        sysTableLookup.performFormLookup();
    }
}

[Vasiliusis]

Еще такой вопрос: как получить значение, которое было выбрано с помощью лукапа?

[Vasiliusis]

И еще один: как в контроле переместить курсор ввода на конец введенной строки?
пока кроме

this.setSelection(strlen(this.text()), strlen(this.text()))

ничего не нашел...

[kvg6]

protected DialogRunBase dialog()
{
    Dialog              dlg;
    FormStringControl   fsc;
    ;
    dlg = super();

    dlgCustAccount      = dlg.addFieldValue(typeId(CustAccount), custAccount);
    fsc                 = dlgCustAccount.control();
    fsc.replaceOnLookup(false);

    return dlg;
}

[AvrDen]

Добрый день. А кто-нибудь делал подобный пример, только на основе BaseEnum, т.е. надо в dialog получить например список Типов операций InventTransType?

[S.Kuskov]

Для энума логичнее использовать группу чекбоксов.

Если принципиально нужно поле с раскрывающимся списком, то я бы смотрел в сторону лукапа по временной таблице.

[Ruff]

Или ListView со свойством CheckBox = Yes

[DSPIC]

AX2012: \Classes\SysLookupMultiSelect
e.g. http://www.dynamics101.com/2014/11/u...amics-ax-2012/