2 и более OUTER JOIN к одному паренту

[Ronin]

Доброго времени суток, вам, господа и дамы!

Не подскажите, как построить селект с 2мя и более outer join'ами с одним парентом? Или объяснить мне в чем я не прав.

У меня на последнем Join'e ругается что

"Невозможно выбрать запись в 'Условия оплаты' ('PaymTerm')
Использован оператор объединения таблиц join, но выражение WHERE не содержит связи между таблицами."

static void Job10(Args _args)
{
SalesTable contractTable;
EmplTable emplTable;
PaymTerm paymTerm;
;

while
select SalesName
from contractTable

outer join NumOfDays, Description
from paymTerm
where paymTerm.PaymTermId == contractTable.Payment

outer join Name
from emplTable
where emplTable.EmplId == contractTable.SalesResponsible

{
info(strfmt("%1 %2", paymTerm.NumOfDays, contractTable.SalesName));
}

}

Хинт: с "обыкновенными", inner join'ами, все job запускается...

[AndyD]

Попробуйте так

    qbDS2.relations(false);                
    qbDS2.addRange(fieldNum(InventDim, InventDimId)).
        value(strfmt("(((%2.dataAreaId == %3.DataAreaId) || (%2.dataAreaId != %3.DataAreaId)) && " +
                     "(%1.inventDimId == %3.inventDimId))",
                        qbDS1.name(), 
                        q.dataSourceTable(tableNum(InventTable)).name(), 
                        qbDS2.name()));

[Perc]

Цитата:

Сообщение от AndyD

Попробуйте так

    qbDS2.relations(false);                
    qbDS2.addRange(fieldNum(InventDim, InventDimId)).
        value(strfmt("(((%2.dataAreaId == %3.DataAreaId) || (%2.dataAreaId != %3.DataAreaId)) && " +
                     "(%1.inventDimId == %3.inventDimId))",
                        qbDS1.name(), 
                        q.dataSourceTable(tableNum(InventTable)).name(), 
                        qbDS2.name()));

Спсб AndyD. Наставил на путь истинный. Я делал почти тоже самое, но наивно решил не заморачиваться с strfmt() в тесте своем и вбивал сразу же условие текстом

    qbDS2.addRange(fieldNum(InventDim, InventDimId)).
        value("(((InventTable.dataAreaId == InventDim.DataAreaId) || (InventTable.dataAreaId != InventDim.DataAreaId)) && (InventSum.inventDimId == InventDim.inventDimId))");

вот это меня и подвело. Ни разу даже мысли не возникло проверить что за текст там получается и как на самом деле датасорсы называются.
Не ошибайтесь так люди

[AndyD]

Можно было явно дать название датасоурсам

qbDS1 = q.addDataSource(tableNum(InventSum), "InventSum");
или qbDS1.Name("InventSum");
и т.д.
Тогда бы ваш вариант работал.

[Wamr]

Хочу отметить, что Job40 (см. тут ) замечательно работает на Oracle и никак не работает на MS SQL.

[vallys]

Цитата:

Сообщение от Wamr

Хочу отметить, что Job40 (см. тут ) замечательно работает на Oracle и никак не работает на MS SQL.

Если перед info добавить

qbDS2.addRange(fieldnum(InventDim, DataAreaId)).value(strfmt(
        "((%1.DataAreaId == %2.DataAreaId) || (%1.DataAreaId != %2.DataAreaId))",
        qbDS2.name(),
        q.dataSourceTable(tablenum(InventTable)).name()
        ));

то и на MS SQL заработает

[Wamr]

а включаешь

PHP код:

    qbDS2 = qbDS1.addDataSource(tableNum(InventDim));
    qbDS2.joinMode(JoinMode::OuterJoin);
    qbDS2.fetchMode(QueryFetchMode::One2One);
    qbDS2.relations(true);
//    qbDS2.addLink(fieldNum(InventSum, InventDimId), fieldNum(InventDim, InventDimId));
    qbDS2.addRange(fieldnum(InventDim, DataAreaId)).value(strfmt(
        "((%1.DataAreaId == %2.DataAreaId) || (%1.DataAreaId != %2.DataAreaId))",
        qbDS2.name(),
        q.dataSourceTable(tablenum(InventTable)).name()
        )); 


- не работает
Наверно, это из-за SaveDataPerCompany = NO

[vallys]

Вот это у меня работает (Ax 3.0 SP 2, MS SQL Server 2000):

static void Job40(Args _args)
{
    Query       q = new Query();
    QueryRun    qr;
    QueryBuildDataSource qbDS1, qbDS2;
    InventSum   inventSum;
    InventTable inventTable;
    InventDim   inventDim;
    ;

    qbDS1 = q.addDataSource(tableNum(InventSum));

    qbDS2 = qbDS1.addDataSource(tableNum(InventTable));
    qbDS2.joinMode(JoinMode::OuterJoin);
    qbDS2.fetchMode(QueryFetchMode::One2One);
    qbDS2.relations(true);

    qbDS2 = qbDS1.addDataSource(tableNum(InventDim));
    qbDS2.joinMode(JoinMode::OuterJoin);
    qbDS2.fetchMode(QueryFetchMode::One2One);
    qbDS2.relations(true);
    qbDS2.addRange(fieldnum(InventDim, DataAreaId)).value(strfmt(
        "((%1.DataAreaId == %2.DataAreaId) || (%1.DataAreaId != %2.DataAreaId))",
        qbDS2.name(),
        q.dataSourceTable(tablenum(InventTable)).name()
        ));

    info(qbDS1.toString());

    qr = new QueryRun(q);
    qr.next();
    inventSum = qr.get(tablenum(InventSum));
    inventTable = qr.get(tablenum(InventTable));
    inventDim = qr.get(tablenum(InventDim));
    info(strfmt("%1 %2 %3", inventSum.ItemId, inventTable.ItemName, inventDim.inventDimId));
}

[vallys]

Sorry - не увидел "SaveDataPerCompany = NO"
Конечно из-за этого, я ж range на DataAreaId цеплял...

ааа... "SaveDataPerCompany = NO" появилось уже после прочтения сообщения мной... тогда понятно, почему не увидел...