экспорт в шаблон excel

[Dimk]

Добрый день!
Знаю, что похожие вещи обсуждались на этом форуме много раз, но всё же...
Есть шаблон MyTemplate.xlt (акт приема на хранение). В шаблоне есть некая шапка (с названием нашей компании), затем несколько столбцов в которые надо положить наши данные, затем несколько ячеек с итогом.
Через ComExcelDocument_RU очень выводится очень медленно, хотелось бы побыстрей, но с сохранением форматирования, которое применяется в шаблоне. Что можете подсказать?

[Delfins]

Это типа использовали буфер обмена и медленно ??

[Dimk]

Нет, буфер обмена не использовал. К сожалению, никак не могу понять, как добавлять в буфер обмена данные и потом их в эксель вставлять в несколько столбцов .

[Zabr]

Цитата:

Сообщение от Dimk

Нет, буфер обмена не использовал. К сожалению, никак не могу понять, как добавлять в буфер обмена данные и потом их в эксель вставлять в несколько столбцов .

Примерно так:

textBuffer   textBuffer = new TextBuffer();
str MyText;
;

while select inventtable
{
  MyText = inventtable.ItemId + num2char(9) // символ 9 - это табуляция для перехода в следующую колонку
              + inventtable.ItemName + num2char(9) 
              + "\n"; // это перевод строки
  textbuffer.appendText(MyText); 
}

file.InsertText("A2", textBuffer); // вставляем буфер начиная с ячейки А2

[Gustav]

Цитата:

Сообщение от Dimk

Нет, буфер обмена не использовал. К сожалению, никак не могу понять, как добавлять в буфер обмена данные и потом их в эксель вставлять в несколько столбцов .

А можно и буфер не напрягать, и в экселе одну-единственную команду для вставки использовать, т.е. одним махом вставить весь ваш предварительно подготовленный в памяти массив данных - несколько столбцов и несколько тысяч строк. Посмотрите джобик здесь. Скорость всего процесса в целом - не наибыстрейшая на Форуме, но очень приличная. А по сравнению с ComExcelDocument_RU (ax3 sp3) - просто сумасшедшая
P.S. Да, и текстовое значение "000333" после вставки останется текстовым значением "000333", не превратившись в число 333.

[Dimk]

всем спасибо, буду разбираться дальше

[gl00mie]

Цитата:

Сообщение от Gustav

А можно и буфер не напрягать, и в экселе одну-единственную команду для вставки использовать, т.е. одним махом вставить весь ваш предварительно подготовленный в памяти массив данных - несколько столбцов и несколько тысяч строк.

Да, CopyFromRecordset - чумовая вещь Единственное, с чем лично я столкнулся в использовании ADODB.Recordset, - это работа в 3-хуровневой конфигурации, когда данные для отчета (и сам Recordset) формируются, как и положено, на сервере, а выводятся в Excel на клиенте. В этом случае необходимо организовать передачу данных на клиента и формировать Recordset там, что я реализовал через небольшой вспомогательный класс. Структура Recordset передается в виде запакованного массива контейнеров [название_поля, тип_поля_ADO], а данные - в виде запакованного Map (номер строки->контейнер данных). Для передачи структуры Recordset Map не подходит - названия колонок отсортируются по алфавиту Выглядит работа примерно так:

#define.ReportTemplateName      ('ReportTemplate.xlt')
// нзвания полей - заголовков табличной части шаблона и названия колонок в RecordSet
#define.fldAccountNum           ('AccountNum')
#define.fldTransDate            ('TransDate')
#define.fldDocumentDesc         ('DocumentDesc')
#define.fldAmount               ('LineAmount')
// названия полей в шапке шаблона
#define.fldHdrLine1             ('headerLine1')
#define.fldHdrLine2             ('headerLine2')
#define.fldHdrLine3             ('headerLine3')
// название ячейки, откуда будет начат вывод строк
#define.fldReportLines          ('reportLines')

// экземпляр Uni_ReportChannelExcel, созданный на клиенте и переданный отчету
Uni_ReportChannel               repChannel;
// ...

{
    Map     mapReport;
    real    nLine; // номер строки данных отчета в Map - вдруг диапазона int не хватит...
    void outputReportHeader()
    {
        UserInfo    userInfo;
        ;
        repChannel.initReportChannel(#ReportTemplatePath_RU + #ReportTemplateName);
        select firstonly name from userInfo where userInfo.id == curuserid();
        repChannel.insertReportValue(#fldHdrLine1,  this.reportTitle());
        repChannel.insertReportValue(#fldHdrLine2,  strfmt("@DIS10758", currencyCode));
        repChannel.insertReportValue(#fldHdrLine3,  strfmt("Отчет сформирован: %1 %2, пользователь: %3",
                                                        today(), time2str(timenow(),0,0), userInfo.name));
        repChannel.insertReportValue(#fldAccountNum,"@DIS8614");
        // и т.д. - вставка полей шапки отчета
    }
    void outputReportBody()
    {;
        repChannel.outputReportBody(mapReport.pack(), #fldReportLines);
    }
    void outputReportFooter()
    {;
        // вставка итоговых полей отчета
        // освобождение используемых COM-объектов
        repChannel.finalize();
    }
    void dumpReportStr(str _p1, TransDate _p2, str _p3, Amount _p4)
    {;
        mapReport.insert(nLine,[_p1,     // #fldAccountNum
                                _p2,     // #fldTransDate
                                _p3,     // #fldDocumentDesc
                                _p4]);   // #fldAmount
        nLine++;
    }
    void initReportStruct()
    {
        #CCADO
        Array   arrFields = new Array(Types::Container);
        int     i = 1;
        ;
        arrFields.value(i, [#fldAccountNum,     #adBSTR]  ); i++;
        arrFields.value(i, [#fldTransDate,      #adDBDate]); i++;
        arrFields.value(i, [#fldDocumentDesc,   #adBSTR]  ); i++;
        arrFields.value(i, [#fldAmount,         #adDouble]);
        repChannel.initReportBuffer(arrFields.pack());
    }
    ;
    // поехали...
    initReportStruct();
    mapReport = new Map(Types::Real, Types::Container);
    nLine = 1.0;

    while select * from tmpTbl
    order by TransDate
    {
        // подготовка данных к выводу и...
        dumpReportStr(tmpTbl.AccountNum, tmpTbl.TransDate, tmpTbl.DocDesc, tmpTable.Amount);
    }
    // вывод в Excel
    outputReportHeader();
    outputReportBody();
    outputReportFooter();
}

[mazzy]

См. также http://axapta.mazzy.ru/lib/direct_sql/

[gl00mie]

Поскольку задача вывода отчетов в Excel все-таки возникает достаточно часто, предыдущие наработки были доведены до ума, в результате чего "канал вывода в Excel" стал более функциональным, а кроме того, появился некий скелет отчета, собирающего данные на сервере и затем использующего этот канал вывода для создания Excel-файла на клиенте, в т.ч. на несколько листов.
Одной из "заковырок" вывода данных в Excel через ADO.Recordset является возникающая порой необходимость как-то избавиться от "незначащих" значений (в основном нулей и дат datenull()) - эта задача и возможные решения, в частности, обсуждаются в исходной теме, благодаря которой и появились эти классы. В доработанном классе вывода в Excel эта задача также была решена, правда, несколько иначе: при необходимости в той или иной колонке табличных данных производится замена средствами самого Excel "незначащих" значений на то, что возвращает COMVariant::createNoValue().

PS. Проект приведен для DAX3

[Gustav]

Цитата:

Сообщение от gl00mie

Проект приведен

Ах, какой я себе кусочек лакомый нашёл в методе clearEmptyCells

// формируем адрес диапазона ячеек *относительно* _cell
strAddr = ComExceldocument_RU::numToNameCell( n, 1 );
if (cnRows > 1)
    strAddr += @':' + ComExceldocument_RU::numToNameCell( n, cnRows );
oRng = _cell.range( strAddr ); // получаем столбец внутри диапазона _cell

oRng.Replace( cvSrcValue, cvDstValue, #xlWhole, #xlByColumns );

Почувствуем разницу:

// получаем столбец внутри диапазона _cell:
// Шаг 1. выбираем n-й столбец по первой строке ("координата X")
// Шаг 2. воображаем этот столбец вниз на cnRows строк ("координата Y")
oRng = _cell.offset( 0, n-1 );     // Шаг 1.
oRng =  oRng.resize( cnRows, 1 );  // Шаг 2. 

oRng.Replace( cvSrcValue, cvDstValue, #xlWhole, #xlByColumns );