Cоздание запроса с агрегатом

[longson]

Написал такой запрос в X++

static void Job103(Args _args)
{
    InventDim            inventDim;
    InventTrans          inventTrans;
    Query                query;
    QueryBuildDataSource qbsInventTrans, qbsInventDim;
    QueryBuildLink       qbl;
    QueryRun             queryRun;
    QueryBuildRange      qbrInventSizeId, qbrStatusIssue, qbrTransType, qbrItemId;
    Qty                  mQty;
    ;

 //   inventDim = this.inventDim();
    query  = new Query();

    qbsInventDim   =  query.addDataSource(tablenum(InventDim));

    qbsInventTrans =  qbsInventDim.addDataSource(tablenum(InventTrans));
   
  //  qbsInventTrans =  qbsInventDim.addDataSource(tablenum(InventTrans));

    qbsInventTrans.relations(true);

    qbsInventTrans.clearLinks();

    qbsInventTrans.addLink(fieldnum(InventDim,inventDimId),fieldnum(InventTrans,inventDimId));

    qbsInventTrans.joinMode(JoinMode::InnerJoin);



    qbrTransType = qbsInventTrans.addRange(fieldnum(InventTrans,TransType));
    qbrTransType.value(queryvalue(InventTransType::Sales));

    qbrStatusIssue = qbsInventTrans.addRange(fieldnum(InventTrans,StatusIssue));
    qbrStatusIssue.value(queryValue(StatusIssue::OnOrder));



    qbsInventDim.orderMode(OrderMode::GroupBy);
    qbsInventDim.addSortField(fieldnum(InventDim,InventSizeId));


    qbsInventTrans.orderMode(OrderMode::GroupBy);
    qbsInventTrans.addSortField(fieldnum(InventTrans,ItemId));
    qbsInventTrans.addSelectionField(fieldnum(InventTrans,ItemId));
    qbsInventTrans.addSelectionField(fieldnum(InventTrans,Qty),SelectionField::Sum);

    queryRun = new QueryRun(query);

    if(queryRun.prompt())
     {
        while(queryRun.next())
         {
            inventTrans = queryRun.get(tablenum(InventTrans));
            inventDim   = queryRun.get(tablenum(InventDim));
            info(strFmt('%1 %2 %3', inventTrans.ItemId, inventDim.InventSizeId, inventTrans.Qty));
         }
     }


}

Когда запускается, в диалоговом окне Запрос в закладке СОРТИРОВКА имеется только поле Размер в таблице Складская аналитика, а поле Номенклатура в таблице Складские проводки отсутствует, в результате выводится только агрегатная сумма для размера, а не для номенклатуры и размера ...

Подскажите пожалуйста, в чем проблема ?

Заранее спасибо.

[Russland]

Закомментируйте строку

//    qbsInventTrans.addSelectionField(fieldnum(InventTrans,ItemId));

и пользуйтесь QueryBrowser

new DEV_QueryBrowser().run(new Query(query));

[kashperuk]

Это я так понимаю в 3ке у вас так?

Я поузнавал по этому поводу. Вот что выяснилось:

Цитата:

Adding Sort Fields
===============
Not supported when group by fields exist; this change was made in Ax 4.0.


Visiblity of Sort Fields
=================
The sorting tab will only show fields for data sources where the orderMode property is set to OrderBy (or fields added via the addOrderByField). This is new to 5.0.

If you want to provide the user with the ability to change the sort order, add the group by fields to the order by list as well.
Ex:
qbsInventDim.addOrderByField(fieldnum(InventDim, InventSizeId));
qbsInventTrans.addOrderByField(fieldnum(InventTrans, ItemId));

Also change the code that uses orderMode(OrderMode::GroupBy) / addSortField(...) to addGroupBy(...). Mixing the orderMode with addOrderByField / addGroupByField is not recommended.
Ex.
replace ...
qbsInventDim.orderMode(OrderMode::GroupBy);
qbsInventDim.addSortField(fieldnum(InventDim, InventSizeId));
with ...
qbdsInventDim.addGroupByField(fieldnum(InventDim, InventSizeId));

Итого, у меня ваш код вообще не отображает полей на закладке сортировки.
Если же переписать чегео addGroupByField (новая фишка в 5ке), то поля отображаются, но удалять/добавлять новые нельзя.

Интересно, кто что думает по-поводу таких изменений, и вообще на связанные темы

[kashperuk]

UP-ну разок.

[longson]

Извините что долго не отвечал. Просто увлекался другими проблемами (тоже Axapta )

Да действительно у меня работа в 3-ке. Я попробую ваш код сегодня (сейчас доступ к Axapta нет).

Я тоже пробовал штук QueryBrowser который Russland рекомендовал, очень полезный. Спасибо. Но у меня тоже страно получилось.

1. При запуске моего кода выводятся в info сгруппированные по размерам, а не по номенклатурам. При этом QueryBrowser показывает сгруппированные по номенклатурам и размерам.
2. Я создал такой же запрос но в AOT. Проверка по QueryBrowser показывает что SQL для этого запроса и для запроса в коде одинаковый. Но запуск AOT-запроса показывает то что я хотел, то есть сгруппированные данные по номенклатурам и размерам.

[longson]

А теперь, если так

static void Job103(Args _args)
{
    InventDim            inventDim;
    InventTrans          inventTrans;
    Query                query;
    QueryBuildDataSource qbsInventTrans, qbsInventDim;
    QueryBuildLink       qbl;
    QueryRun             queryRun;
    QueryBuildRange      qbrInventSizeId, qbrStatusIssue, qbrTransType, qbrItemId;
    Qty                  mQty;
    ;

    query  = new Query();

    qbsInventTrans = query.addDataSource(tablenum(InventTrans));

    qbsInventDim   = qbsInventTrans.addDataSource(tablenum(InventDim));

    qbsInventDim.relations(true);

    qbrTransType = qbsInventTrans.addRange(fieldnum(InventTrans,TransType));
    qbrTransType.value(queryvalue(InventTransType::Sales));

    qbrStatusIssue = qbsInventTrans.addRange(fieldnum(InventTrans,StatusIssue));
    qbrStatusIssue.value(queryValue(StatusIssue::OnOrder));

    qbsInventDim.orderMode(OrderMode::GroupBy);
    qbsInventDim.addSortField(fieldnum(InventDim, InventSizeId));


    qbsInventTrans.orderMode(OrderMode::GroupBy);
    qbsInventTrans.addSortField(fieldnum(InventTrans, ItemId));
    
    qbsInventTrans.addSelectionField(fieldnum(InventTrans,Qty),SelectionField::Sum);
    qbsInventTrans.addSelectionField(fieldnum(InventTrans,ItemId));

    queryRun = new QueryRun(query);

    if(queryRun.prompt())
     {
        while(queryRun.next())
         {
            
            
            inventTrans = queryRun.get(tablenum(InventTrans));
            inventDim   = queryRun.get(tablenum(InventDim));
            info(strFmt('%1 %2 %3', inventTrans.ItemId, inventDim.InventSizeId, inventTrans.Qty));
         }
     }

}

Т.е, просто изменение порядок таблицы InventTrans и InventDim в запросе, то выводятся сгруппированные данные по номенклатурам, а не по номенклатурам и размерам.

Мне кажется, что что - то неправильно имеено в кускочке кода

    if(queryRun.prompt())
     {
        while(queryRun.next())
         {
            
            
            inventTrans = queryRun.get(tablenum(InventTrans));
            inventDim   = queryRun.get(tablenum(InventDim));
            info(strFmt('%1 %2 %3', inventTrans.ItemId, inventDim.InventSizeId, inventTrans.Qty));
         }

Или я что - то ещё не понимаю ? Почему выводятяся только сгруппированные данные именно по полю родительского источника данных ?

[kashperuk]

В АХ 5 Queries в АОТ были изменены, и теперь в них возможно добавлять группировку и сортировку ТОЛЬКО на уровне всего запроса (причем можно и то, и то).
Соответственно, в форме запроса можно менять сортировку, и она выводится в соответствии с вашими ожиданиями.

А про ваш запрос - мне это очень похоже на какой-то глюк - я много раз писал запросы такого рода - и всегда работало.

[longson]

Можете пробовать такой на своем AX. Я очень надеюсь, что это не глюк, а какая-то ошибка которую я допустил . Спасибо.

[kashperuk]

Цитата:

Сообщение от longson

Можете пробовать такой на своем AX. Я очень надеюсь, что это не глюк, а какая-то ошибка которую я допустил . Спасибо.

Если это ко мне, то см. 3ье сообщение в теме. У меня это воспроизвести не получится из-за изменений, сделанных в 4.0