Group by и временная таблица

[S.Kuskov]

AX 4.0 SP2

Тестируя отчёт, случайно поймал глюк:

static void job(Args _args)
{
    tmpTable tmpTable;
    counter cnt;
    ;

    tmpTable.clear();
    tmpTable.Field1 = '1';
    tmpTable.insert();

    tmpTable.clear();
    tmpTable.Field1 = '1';
    tmpTable.insert(); // вставляем две одинаковые строки

    cnt = 0;
    while select tmpTable
    group by Field1
//    where tmpTable.Field1 == '1'
    {
        cnt++;
    }

    info(int2str(cnt));
}

Если раскомментировать предложение WHERE то цикл выполнится 2 раза! У кого-нибудь воспроизводится?

P.S.: Обязательные условия: таблица - временная; поле - текстовое

[Varmen]

а это не потому что,
select TmpTable = select * from TmpTable, т.е со всей тучей полей типа RecId itd?

Группировка соответсвенно тут не помогает.


Т.е нужно явно написать

select Field1 from tmpTable
group by Field1

[S.Kuskov]

Не помогает . И к тому же без where - работает корректно!

[ZVV]

Цитата:

Сообщение от Varmen

а это не потому что,
select TmpTable = select * from TmpTable, т.е со всей тучей полей типа RecId itd?

Группировка соответсвенно тут не помогает.


Т.е нужно явно написать

select Field1 from tmpTable
group by Field1

Нужели вы каждый раз так пишете при группировке?
Аксапта сама этот момент "распознаёт", так что явно писать вовсе не обязательно.

[Varmen]

ага, особенно когда join , не раз палился. при поиске ошибки, лучше явно поставить, дабы исключить разную трактовку ситуации.

[S.Kuskov]

Цитата:

Сообщение от Varmen

ага, особенно когда join , не раз палился. при поиске ошибки, лучше явно поставить, дабы исключить разную трактовку ситуации.

А пример можете привести, когда явное указания выбираемых полей, участвующих в группировке, хоть как-то влияет на результат?

Цитата:

Сообщение от ZVV

Аксапта сама этот момент "распознаёт", так что явно писать вовсе не обязательно.

+1

[Varmen]

не, не смогу такое привести.
Но ведь Вы мною предложенный вариант попробовали правда? Знаете почему, потому что jobik не работает так как изначально задумали, а причина неизвестна.

[S.Kuskov]

не работает "как задумали" - мягко сказано

Если фильтровать текстовое поле, участвующее в группировке, то group by попросту игнорируется! (причём, например, для целочисленного поля тот же код отрабатывает корректно )

Что я делаю не так?
Кто-нибудь может прокомментрировать такое поведение group by? Это следствие каких-то известных (документированных) ограничений?
И какие ещё сюрпризы от использования временных таблиц можно ожидать?

[Varmen]

могу подвердить, зашел на нашу систему, также исполняется два раза.
Ах4.0сп2

[Varmen]

баг можно побороть, если вставить не явно поле, как я предпологал выше, а функцию агрегации над ним. Тогда аксапта "распознает" что таки надо группировать!

  while select maxof(Field1) from  t
  group by Field1
   where t.Field1 == '1'
   {
    info(strfmt("fisrt query %1",t.Field1));
   }

[Varmen]

static void Job10(Args _args)
{
 TempDummyTable t;
 ;
ttsbegin;
   t.Field1="1";
   t.insert();
ttscommit;
ttsbegin;
   t.Field1="1";
   t.insert();
ttscommit;
 
   
   while select maxof(Field1) from  t
  group by Field1
   where t.Field1 == '1'
   {
    info(strfmt("fisrt query %1",t.Field1));
   }
 
    while select t
  group by Field1
  where t.Field1 == '1'
   {
    info(strfmt("second query %1",t.Field1));
   }
}

Сообщение (21:28:38)
fisrt query 1
second query 1
second query 1

[Varmen]

Ну что смеемся дальше?
добавим поле Фиелд2

static void Job10(Args _args)
{
 TempDummyTable t;
 ;
ttsbegin;
   t.Field1="1";
   t.Field2="2";
   t.insert();
ttscommit;
ttsbegin;
   t.Field1="1";
   t.Field2="4";
   t.insert();
ttscommit;
 
   
   while select maxof(Field1) from  t
  group by Field1
   where t.Field1 == '1'
   {
    info(strfmt("fisrt query %1--%2",t.Field1,t.Field2));
   }
 
    while select t
  group by Field1
  where t.Field1 == '1'
   {
    info(strfmt("second query %1--%2",t.Field1,t.Field2));
   }
}

Сообщение (21:37:37)
fisrt query 1--
second query 1--2
second query 1--4

Ну куда группировка делась, во втором случае?

[Varmen]

ну и под занавес, мой любимый RecId itd

static void Job10(Args _args)
{
 TempDummyTable t;
 ;
ttsbegin;
   t.Field1="1";
   t.Field2="2";
   t.insert();
ttscommit;
ttsbegin;
   t.Field1="1";
   t.Field2="4";
   t.insert();
ttscommit;
 
 
   while select maxof(Field1) from  t
  group by Field1
   where t.Field1 == '1'
   {
    info(strfmt("fisrt query %1--%2",t.Field1,t.Field2));
   }
 
    while select t
  group by Field1
  where t.Field1 == '1'
   {
    info(strfmt("second query %1--%2--%3",t.Field1,t.Field2,t.RecId));
   }
}
 
 (21:44:51)
fisrt query 1--
second query 1--2--1328
second query 1--4--1376

[ZVV]

Цитата:

Сообщение от Varmen

....
Ну куда группировка делась, во втором случае?

Вы имеете ввиду, что результаты никак не сгруппировались вобще и в остальных колонках тоже есть данные? Ну мне кажется это сразу было очевидно, что Аксапта "забыла" сделать груп_бай вообще. Например можно было попробовать вставить не 2, а 3 или 4 строки.

По сути... Проверил на DAX2009 SP1 - результат абсолютно тот же. Реальный баг. Видимо разработчики такой вырожденный случай тупо забыли/не подумали закодить. ))
Почему "вырожденный"? Ну потому что вы по сути хотите выяснить есть ли у вас хоть одна строка со значением "1". С точки зрения производительности и логики я думаю лучше было бы написать этот запрос примерно так:

    while select firstFast firstOnly Field1 from tmpTable
    where tmpTable.Field1 == '1'

, чем гонять зря группировку...
Так работает...

[DSPIC]

Цитата:

Сообщение от ZVV

Вы имеете ввиду, что результаты никак не сгруппировались вобще и в остальных колонках тоже есть данные? Ну мне кажется это сразу было очевидно, что Аксапта "забыла" сделать груп_бай вообще. Например можно было попробовать вставить не 2, а 3 или 4 строки.

По сути... Проверил на DAX2009 SP1 - результат абсолютно тот же. Реальный баг. Видимо разработчики такой вырожденный случай тупо забыли/не подумали закодить. ))
Почему "вырожденный"? Ну потому что вы по сути хотите выяснить есть ли у вас хоть одна строка со значением "1". С точки зрения производительности и логики я думаю лучше было бы написать этот запрос примерно так:

    while select firstFast firstOnly Field1 from tmpTable
    where tmpTable.Field1 == '1'

, чем гонять зря группировку...
Так работает...

Не совсем согласен с вырожденностью. Я, например, хочу получить итоговые суммы по отделам, наименования которых начинаются на "OUT*"

 while select sum (amount) from tmpTable
    group by department
      where tmpTable.department like 'OUT*'
    {
        info(strFmt("%1 - %2", tmpTable.department, tmpTable.amount));
    }

(не знаю, правда, как like поведет себя в данном случае, но не суть)

[Varmen]

или скажем узнать кол-во уволенных сотрудников в связи с кризисом по отделам, имеющим признак ="CLOSED"

[S.Kuskov]

Цитата:

Сообщение от Varmen

узнать кол-во уволенных сотрудников в связи с кризисом по отделам, имеющим признак ="CLOSED"

Можно. Вы же сами предложили выход

Цитата:

Сообщение от Varmen

баг можно побороть, если вставить не явно поле, как я предпологал выше, а функцию агрегации над ним. Тогда аксапта "распознает" что таки надо группировать!

Т.е. такая конструкция всётаки работает

  while select maxof(Field1), count(RecId) from  t
  group by Field1
   where t.Field1 == '1'
   {
    info(strfmt("fisrt query %1 %2",t.Field1, t.RecId));
   }

[S.Kuskov]

Цитата:

Сообщение от DSPIC

Не совсем согласен с вырожденностью. Я, например, хочу получить итоговые суммы по отделам, наименования которых начинаются на "OUT*" (не знаю, правда, как like поведет себя в данном случае)

С like всё теже самые проблемы


А по поводу вырожденности случая - не всегда удобно обробатывать его отдельно. Например, я часто использую в условии запроса такую конструкцию

((prmValue == "") || (Table.Field1 == prmValue))

Т.е. если пользователь не хочет ограничивать запрос, то он оставляет параметр пустым, иначе должна выбраться только одна группа. Или даже так

((prmValue == "") || (Table.Field1 like prmValue))

P.S.: Вот сижу сейчас и думаю, как же я раньше на такие грабли не наступал? Может действительно пример искуственен, а в жизни есть какая-то комбинация дополнительных условий, которая всегда спасала?

[ZVV]

Цитата:

Сообщение от DSPIC

Не совсем согласен с вырожденностью. Я, например, хочу получить итоговые суммы по отделам, наименования которых начинаются на "OUT*"

 while select sum (amount) from tmpTable
    group by department
      where tmpTable.department like 'OUT*'
    {
        info(strFmt("%1 - %2", tmpTable.department, tmpTable.amount));
    }

(не знаю, правда, как like поведет себя в данном случае, но не суть)

Говоря о вырожденном случае, я имел ввиду случай из примера:

   while select tmpTable
    group by Field1
    where tmpTable.Field1 == '1'

, где "вы по сути хотите выяснить есть ли у вас хоть одна строка со значением "1"". Приведённый вами пример - это совсем другой, не вырожденный случай, и выше было показано, что при наличии агрегирующих функций в запросе баг не воспроизводится...
К чему придираемся?

[S.Kuskov]

Цитата:

Сообщение от Lemming

p.s. Знатный оффтопик получился

Предлагаю вынести сообщения #19, 20, 22-31 в отдельную тему "Временным таблицам фиолетово на транзакции"


--- Модератор: оффтопик перенесен в Временные таблицы и транзакции ---