Помогите при запросе ...

[Rimantas]

Здраствуйте ,

Есть стандартная аналитика и станд. query в рапорте : InventDim -> InventSum -> InventTable ... Дело в том что хочу немножко поправить запрос , но неполучаеться .
Мое желание :

PHP код:

      while select inventSum index hint LocateItemIdx where
      inventSum.InventLocationId == cInvLoc
      exists join firstonly invTrn index hint ItemIdx where
      invTrn.ItemId       == inventSum.ItemId      &&
      invTrn.inventDimId  == inventSum.InventDimId &&
      invTrn.DatePhysical >= dBgn 


Я пробывал вот так ...

PHP код:

   qr = new QueryRun( element.query() );
   qbds1 = qr.query().dataSourceName( "InventSum" ).addDataSource( tableNum( InventTrans ) );
   qbds1.fetchMode( joinMode::ExistsJoin );
   // qbds1.relations( false );
   qbds1.firstOnly( true );
   qbds1.sortIndex( indexnum( InventTrans, ItemIdx ) );
   qbds1.addLink( fieldnum( InventSum, ItemId ), fieldnum( InventTrans, ItemId ) );
   qbds1.addLink( fieldnum( InventSum, InventDimId ), fieldnum( InventTrans, InventDimId ) );
   qbds1.addRange( fieldnum( InventTrans, DatePhysical ) ).value( 'invTrn.DatePhysical >= dBgn' ); 


Но пока выбрасывает ошибку , что какая то 4 стрелка неправильна ... :-( . Что я здесь плохо делаю ?

Спасибо заранее ! С уважением , Римантас

[S.Kuskov]

Вы знакомы с http://www.axaptapedia.com/index.php...ultiple_tables?

Хотя, сейчас присмотрелся к запросу. Расширенный синтаксис там вообще не нужен. Вам же просто нужно коректно записать условие '>=' http://axapta.mazzy.ru/lib/search/

[Russland]

А таблицы слинкованы правильно?
В смысле без наложения условия по DatePhysical запрос работает?

   qr = new QueryRun( element.query() );
   qbds1 = qr.query().dataSourceName( "InventSum" ).addDataSource( tableNum( InventTrans ) );
   qbds1.fetchMode( joinMode::ExistsJoin );
   // qbds1.relations( false );
   qbds1.firstOnly( true );
   qbds1.sortIndex( indexnum( InventTrans, ItemIdx ) );
   qbds1.addLink( fieldnum( InventSum, ItemId ), fieldnum( InventTrans, ItemId ) );
   qbds1.addLink( fieldnum( InventSum, InventDimId ), fieldnum( InventTrans, InventDimId ) );
//   qbds1.addRange( fieldnum( InventTrans, DatePhysical ) ).value( 'invTrn.DatePhysical >= dBgn' );

[lev]

меня смущает вот эта строка:

qbds1.addRange( fieldnum( InventTrans, DatePhysical ) ).value( 'invTrn.DatePhysical >= dBgn' );

получается в value вы сравниваете дату со строковым значением dBgn... , более того, условие по умолчанию так не пишется вроде.
может там должно быть что то типа

qbds1.addRange( fieldnum( InventTrans, DatePhysical ) ).value(strFmt('%1..', dBgn ));

[lev]

ещё немного подумал, и решил что совсем красиво будет так:

qbds1.addRange( fieldnum( InventTrans, DatePhysical ) ).value(SysQuery::range(dBgn, dateMax()));

[Rimantas]

Цитата:

Сообщение от lev

ещё немного подумал, и решил что совсем красиво будет так:

qbds1.addRange( fieldnum( InventTrans, DatePhysical ) ).value(SysQuery::range(dBgn, dateMax()));

Спасибо за советы . Попробывал такое собрать :

PHP код:

q = element.query();
qr = new QueryRun( q );

qbds1 = query.dataSourceTable( tableNum( InventSum ) );
qrn4  = qbds1.addRange( fieldNum( inventSum, InventLocationId ) );
qrn4.value( cInvLoc );

qbds2 = query.addDataSource( tableNum( InventTrans ), "InventTrans" );
qbds2.joinMode( JoinMode::ExistsJoin );
qbds2.firstOnly( true );

qrn1 = qbds2.addRange( fieldNum( InventTrans, ItemId ) );
qrn1.value( strFmt( 'inventTrans.ItemId == inventSum.ItemId' ) );

qrn2 = qbds2.addRange( fieldNum( InventTrans, InventDimId ) );
qrn2.value( strFmt( 'inventTrans.InventDimId == inventSum.InventDimId' ) );

qrn3 = qbds2.addRange( fieldNum( InventTrans, DatePhysical ) );
qrn3.value( SysQuery::range( dBgn, dateMax() ) ); 


Ето возвращяет такие селекты :

SELECT * FROM InventSum WHERE InventDim.inventDimId = InventSum.InventDimId AND ((ItemId = 1062A)) AND ((InventLocationId = LS nukain.50)) JOIN * FROM InventTable WHERE InventSum.ItemId = InventTable.ItemId

SELECT FIRSTONLY * FROM InventTrans WHERE ((ItemId = inventTrans.ItemId == inventSum.ItemId)) AND ((inventDimId = inventTrans.InventDimId == inventSum.InventDimId)) AND ((DatePhysical>=2010.01.01 AND DatePhysical<=2153.12.31))

Но - while ( qr.next() ) - пустой ... А по простому селекту ( в первом сообщении while select ... ) - все работает ... Чего ещё нехватает ?

[lev]

просто немного не правильный ситаксис.
во первых QueryRun надо инициализировать после того как собрали Query...
предполагаю что Ваш запрос должен выглядеть так (это пример):

Query                   query;
    QueryBuildDataSource    qbdsInventSum, qbdsInventTrans;
    QueryBuildRange         qbr;
    QueryRun                qr;
    InventLocationId        cInvLoc;
    TransDate               dBgn;
    ;

    query = element.Query();

    qbdsInventSum = query.dataSourceTable(tableNum(InventSum));
    qbr = qbdsInventSum.addRange(fieldNum(InventSum, InventLocationId));
    qbr.value(QueryValue(cInvLoc));

    qbdsInventTrans = qbdsInventSum.addDataSource(tableNum(InventTrans));
    qbdsInventTrans.addLink(fieldNum(InventSum, ItemId), fieldNum(InventTrans, ItemId));
    qbdsInventTrans.addLink(fieldNum(InventSum, InventDimId), fieldNum(InventTrans, InventDimId));
    qbdsInventTrans.joinMode(JoinMode::ExistsJoin);
    qbdsInventTrans.firstOnly(true);

    qbr = qbdsInventTrans.addRange(fieldNum(InventTrans, DatePhysical));
    qbr.value(SysQuery::range(dBgn, dateMax()));

    qr = new QueryRun(query);

[Rimantas]

Цитата:

Сообщение от lev

просто немного не правильный ситаксис.
во первых QueryRun надо инициализировать после того как собрали Query...
предполагаю что Ваш запрос должен выглядеть так (это пример):

Query                   query;
    query = element.Query();

    qbdsInventSum = query.dataSourceTable(tableNum(InventSum));
    qbr = qbdsInventSum.addRange(fieldNum(InventSum, InventLocationId));
    qbr.value(QueryValue(cInvLoc));

    qbdsInventTrans = qbdsInventSum.addDataSource(tableNum(InventTrans));
    qbdsInventTrans.addLink(fieldNum(InventSum, ItemId), fieldNum(InventTrans, ItemId));
    qbdsInventTrans.addLink(fieldNum(InventSum, InventDimId), fieldNum(InventTrans, InventDimId));
    qbdsInventTrans.joinMode(JoinMode::ExistsJoin);
    qbdsInventTrans.firstOnly(true);

    qbr = qbdsInventTrans.addRange(fieldNum(InventTrans, DatePhysical));
    qbr.value(SysQuery::range(dBgn, dateMax()));
    qr = new QueryRun(query);

Спасибо за помочь . Скопировал , обработал - но всё таки ещё пусто ... Но направление как и ясно , буду искать дальше ...

С уважением , Римантас

[Rimantas]

Цитата:

Сообщение от lev

просто немного не правильный ситаксис.
во первых QueryRun надо инициализировать после того как собрали Query...
предполагаю что Ваш запрос должен выглядеть так (это пример):

Query                   query;
    QueryBuildDataSource    qbdsInventSum, qbdsInventTrans;
    QueryBuildRange         qbr;
    QueryRun                qr;
    InventLocationId        cInvLoc;
    TransDate               dBgn;
    ;

    query = element.Query();

    qbdsInventSum = query.dataSourceTable(tableNum(InventSum));
    qbr = qbdsInventSum.addRange(fieldNum(InventSum, InventLocationId));
    qbr.value(QueryValue(cInvLoc));

    qbdsInventTrans = qbdsInventSum.addDataSource(tableNum(InventTrans));
    qbdsInventTrans.addLink(fieldNum(InventSum, ItemId), fieldNum(InventTrans, ItemId));
    qbdsInventTrans.addLink(fieldNum(InventSum, InventDimId), fieldNum(InventTrans, InventDimId));
    qbdsInventTrans.joinMode(JoinMode::ExistsJoin);
    qbdsInventTrans.firstOnly(true);

    qbr = qbdsInventTrans.addRange(fieldNum(InventTrans, DatePhysical));
    qbr.value(SysQuery::range(dBgn, dateMax()));

    qr = new QueryRun(query);

Лев , БОЛЬШОЕ СПАСИБО ! Всё работает . Просто я забыл поставит после next :
InventSum = qr.get( tableNum( InventSum ) ); ... :-)

[lev]

бывает
на здоровье