Kernel version - нужно ли обновлять?

[Poleax]

Цитата:

Сообщение от Corel

Понял, действительно с клиентом нестыковка. Почему-то был уверен, что Kernel - что-то более глобальное. Спасибо, насчёт массовой установки тоже полезная ссылочка.

про Kernel согласен название оригинальное. Хотя это версия клиенской ПО.

в Массовое развертывание клиентов Dynamics Ax 2009
использую на SMS Server рассылку группе в AD скрипта BAT - файл

@ECHO OFF

set Distr_Ax=\\srv-fs-01\Deploy$\"Microsoft Dymanics Axapta"\
set PATH_dotNET="%SystemRoot%\Microsoft.NET\Framework\v3.5\vbc.exe"
set PATH_Rollup="%ProgramFiles%\Microsoft Dynamics AX\50\Client\Log\SP1RU7UpdateLog.txt"
set PATH_SP="%ProgramFiles%\Microsoft Dynamics AX\50\Client\Log\SP1UpdateLog.txt"
set PATH_Ax="%ProgramFiles%\Microsoft Dynamics AX\50\Client\Bin\ax32.exe"

@ECHO Disk Mapping
@net use m: \\dc2\NETLOGON\scripts


@ECHO Validating Install Package
@if exist %PATH_Rollup% goto INSTALLED
@if exist %PATH_SP% goto INSTALLRollup
@if exist %PATH_Ax% goto INSTALLSP1

@if exist %PATH_dotNET% goto INSTALLAX

:NOTNETINSTALLED
@ECHO Installing .NET Framework 3.5 SP1
@START/w %Distr_Ax%"Ax_2009_ISO\_NET\Microsoft .NET Framework 3.5 Service pack 1.exe" /q /norestart

:LOOPTRANS
if not exist %PATH_dotNET% goto LOOPTRANS

:INSTALLAX
@ECHO Starting installation Dynamics Ax 2009 
@START/w %Distr_Ax%"Ax_2009_ISO\Setup.exe" LogDir="%ProgramFiles%\Microsoft Dynamics AX\50\Client\Log\AX2009Log.txt" InstallPath="%ProgramFiles%\Microsoft Dynamics AX\50" InstallPath32Bit="%ProgramFiles%\Microsoft Dynamics AX\50" HideUI=1 AcceptLicenseTerms=1 InstallClientUI=1 ClientAosServer="DynamicsAx2009@Srv-axp-app-01" ClientLanguage=ru ClientHelpLanguages=ru ConfigurePrerequisites=1

:LOOPTRANS2
@if not exist %PATH_Ax% goto LOOPTRANS2
@GOTO INSTALLSP1

:INSTALLSP1
@ECHO Starting installation of Dynamics Ax 2009 SP1
@START/w %Distr_Ax%"SP1\axupdate.exe" LogDir=%PATH_SP% HideUI=1 AcceptLicenseTerms=1 InstallComponents=1

:LOOPTRANS3
@if not exist %PATH_SP% goto LOOPTRANS3

:INSTALLRollup
@ECHO Starting installation of Dynamics Ax 2009 SP1 Rollup 7
@START/w %Distr_Ax%"RU7\axupdate.exe" LogDir=%PATH_Rollup% HideUI=1 AcceptLicenseTerms=1 InstallComponents=1

:LOOPTRANS4
@if not exist %PATH_Rollup% goto LOOPTRANS4
rem @GOTO COMPLETE

:COMPLETE
@ECHO Installation complete.
@GOTO END

:INSTALLED
@ECHO SP1 Client Already Installed
@GOTO END

:END

@ECHO Delete Disk Mapping
@net use m: /delete /y

@ECHO The end :)
set PATH_Rollup=
set PATH_SP=
set PATH_Ax=
set PATH_dotNET=
set Distr_Ax=

Этот же скрипт обновляет пользователям Rollup c 6 до 7.