NoExistsJoin и addRange

[Deepoint]

Здравствуйте уважаемые.
Вот с такой проблемой столкнулся:
есть код

QueryBuildDataSource qbdsMain = query.dataSourceTable(tablenum(BankPaymentOrderJour_RU));
QueryBuildDataSource qbdsLedgerJoined;
qbdsLedgerJoined  = qbdsMain.addDataSource(tablenum(BankAccountTrans),'BankAccountTrans');
            if (bankPaymentOrderJourReport_RU.dimension())
            {
               qbdsLedgerJoined.addRange(fieldId2Ext(fieldnum(BankAccountTrans, Dimension),1)).value(bankPaymentOrderJourReport_RU.dimension());
            }
            qbdsLedgerJoined.relations(true);
            qbdsLedgerJoined.joinMode(JoinMode::NoExistsJoin);

Собственно в случае если bankPaymentOrderJourReport_RU.dimension() установлен запрос возвращает некорректные значения, а именно нет фильтра на этот самый dimension. Буду признателен за любой совет или помощь.

[pitersky]

То, что нет фильтра - неудивительно. NotExistsJoin всего лишь позволяет отобрать те записи, которым нет соответствия в подчинённом датасоурсе. Никакие фильтры на него наложить не получится. Для этого нужен InnerJoin

[Deepoint]

А какие варианты решения данной проблемы могут быть? Мне нужны записи из таблицы BankPaymentOrderJour_RU которых нет в BankAccountTrans и у которых, опять же, в BankAccountTrans есть заданный Dimension.

[S.Kuskov]

Цитата:

Сообщение от Deepoint

Мне нужны записи из таблицы BankPaymentOrderJour_RU которых нет в BankAccountTrans и у которых, опять же, в BankAccountTrans есть заданный Dimension.

Ну вы и формулируете

Если я правильно понял задачу, то вы хотите отобрать все записи BankPaymentOrderJour_RU для которых в таблице BankAccountTrans нет записей с указанным Dimension.

Dimension - это масив? Коли так, то range нужно накладывать отдельно на каждый фильтруемый элемент масива

dimension = bankPaymentOrderJourReport_RU.dimension();
qbdsLedgerJoined.addRange(fieldId2Ext(fieldnum(BankAccountTrans, Dimension),1)).value(dimension[1])

[pitersky]

Думаю, что дело тут не в Range, а в

qbdsLedgerJoined.relations(true);

скорее всего связь идёт по номеру ваучера. А в данном контексте это неправильно. Надо убрать указанную строчку и добавить для qbdsLedgerJoined несколько addLink, по 1 на каждую финаналитику. А уж потом использовать NotExistsJoin

[Deepoint]

Цитата:

Сообщение от pitersky

Думаю, что дело тут не в Range, а в

qbdsLedgerJoined.relations(true);

скорее всего связь идёт по номеру ваучера. А в данном контексте это неправильно. Надо убрать указанную строчку и добавить для qbdsLedgerJoined несколько addLink, по 1 на каждую финаналитику. А уж потом использовать NotExistsJoin

Опробовал Ваш вариант, к сожалению результат все тот же. Но все равно спасибо.

[S.Kuskov]

После формирования query, в качестве самоконтроля, можно вывести в инфолог текст получившегося SQL-запроса.

info(query.DataSourceNo(1).toString());

Посмотрев на него сразу станет понятно каких релейшинов или ранджей не хватает

[Лиса-а-а]

помогите перевести вот этот запрос с SQL в нечно красивейшее через QueryBuildDataSource

Select VendInvoiceJour.InvoiceDate,VSN_PURCHORDERJOUR.CENTERPROFIX,VendInvoiceTrans.ItemId   from VendInvoiceJour
inner join VendInvoiceTrans on VendInvoiceTrans.PurchId = VendInvoiceJour.PurchId
inner join PurchTable on PurchTable.PurchId  = VendInvoiceTrans.PurchId
inner join PurchLine on PurchLine.PurchId  = PurchTable.PurchId 
inner join VSN_PURCHORDERJOUR on VSN_PURCHORDERJOUR.ORDERID = PurchLine.VSN_PURCHORDERID
where VSN_PURCHORDERJOUR.CENTERPROFIX= '008-001' and
 VendInvoiceJour.InvoiceDate >= '2011/03/01'
and VendInvoiceJour.InvoiceDate <= '2011/03/20'

или может скиньте какой нить пример где больше 2х таблиц связывается
и может есть у кого нить ссылки на литературу по этому делу на русском языке?

[S.Kuskov]

Нет никаких принципиальных отличий между добавлением второй таблицы и добавлением последующих. Лиса-а-а, вы попробуйте, если не получиться, то выложите свой код, кто-нибудь обязательно поможет и заодно раскажет в чём была проблема.

Получить готовое решение с нуля как-то не педагогично

[ice]

если вы пытались и у вас не получилось, то скорее всего у вас ошибка в fetchmode, нужно всем соединяемым таблицам задать:

    qbds.fetchMode(QueryFetchMode::One2One);

[Лиса-а-а]

такс.. начинаю с малого, но и тут засада

   Query                   query = this.queryRun().query();
    QueryBuildDataSource    
    dataSourceJourTest  = query.addDataSource(tableNum(VendInvoiceJour));

    dataSourceJourTest  = dataSourceJourTest.addDataSource(VendInvoiceTrans,'VendInvoiceTrans');
 
    dataSourceJourTest.addLink(fieldnum(VendInvoiceTrans, PurchId), fieldnum(VendInvoiceJour, PurchId));
   dataSourceJourTest.relations(true);
    dataSourceJourTest.joinMode(joinMode::ExistsJoin);

addLink ак будто вообще не видит соединяет автоматомм по всему на свети
если dataSourceJourTest.relations(true); убераю то вообще по каким то непонятным палям их цепляет

[SRF]

dataSourceJourTest.addLink(fieldnum(VendInvoiceJour, PurchId), fieldnum(VendInvoiceTrans, PurchId));

ПС. Вообще, хорошие ссылки по книжкам и ресурсам есть на главной странице, раздел "Полезное". Иногда помогает поиск по AOT, по ключевым словам, поищите в классах addLink, найдете массу примеров как его использовать.

[Maxim Gorbunov]

Лиса-а-а,

Во-первых, почему вы делаете joinMode(JoinMode::ExistsJoin), если в SQL запросе, который вы хотите получить, везде inner join?

Во-вторых, relations(true) автоматически загружает связи между таблицами из AOT. Соответственно, все те связи, что вы в явном виде определили заранее перед этим через addLink(), будут проигнорированы.

В-третьих, в addLink() первый параметр - fieldId поля из таблицы верхнего уровня, а второй - из таблицы текущего уровня. То есть, в вашем случае должно быть так:

dataSourceJourTest.addLink(fieldnum(VendInvoiceJour, PurchId), fieldnum(VendInvoiceTrans, PurchId));

В-четвёртых, не игнорируйте Developer Help (тот, который можно открыть из клиента AX). Его легко можно прочитать за день, и найти ответы на большинство интересующих вас вопросов.

[Maxim Gorbunov]

Да, и в догонку - связывать VendInvoiceJour и VendInvoiceTrans только по PurchId неправильно. Задумайтесь о том, что будет, если по одной закупке будет проведено две накладных.

[raz]

qbds = query.addDataSource(tableNum(VendInvoiceJour));
qbds.addRange(fieldnum(VendInvoiceJour, InvoiceDate)).value(QueryRange('2011/03/01','2011/03/20'));
qbds.addRange(fieldnum(VendInvoiceJour, CENTERPROFIX)).value(QueryValue('008-001'));

qbds = qbds.addDataSource(tableNum(VendInvoiceTrans));
qbds.relations(false);
qbds.joinMode(joinMode::InnerJoin);
qbds.addLink(fieldnum(VendInvoiceJour, PurchId), fieldnum(VendInvoiceTrans, PurchId));

qbds = qbds.addDataSource(tableNum(PurchTable));
qbds.relations(false);
qbds.joinMode(joinMode::InnerJoin);
qbds.addLink(fieldnum(VendInvoiceJour, PurchId), fieldnum(PurchTable, PurchId));

qbds = qbds.addDataSource(tableNum(PurchLine));
qbds.relations(false);
qbds.joinMode(joinMode::InnerJoin);
qbds.addLink(fieldnum(PurchTable, PurchId), fieldnum(PurchLine, PurchId));

qbds = qbds.addDataSource(tableNum(VSN_PURCHORDERJOUR));
qbds.relations(false);
qbds.joinMode(joinMode::InnerJoin);
qbds.addLink(fieldnum(PurchLine, VSN_PURCHORDERID), fieldnum(VSN_PURCHORDERJOUR, ORDERID));
qbds.addRange(fieldnum(VSN_PURCHORDERJOUR, CENTERPROFIX)).value(QueryValue('008-001'));


// правильнее

qbds = query.addDataSource(tableNum(VendInvoiceJour));
qbds.addRange(fieldnum(VendInvoiceJour, InvoiceDate)).value(QueryRange('2011/03/01','2011/03/20'));
qbds.addRange(fieldnum(VendInvoiceJour, CENTERPROFIX)).value(QueryValue('008-001'));

qbds = qbds.addDataSource(tableNum(VendInvoiceTrans));
qbds.relations(false);
qbds.joinMode(joinMode::InnerJoin);
qbds.addLink(fieldnum(VendInvoiceJour, PurchId), fieldnum(VendInvoiceTrans, PurchId));
qbds.addLink(fieldnum(VendInvoiceJour, PurchId), fieldnum(VendInvoiceTrans, PurchId));
qbds.addLink(fieldnum(VendInvoiceJour, InvoiceId), fieldnum(VendInvoiceTrans, InvoiceId));
qbds.addLink(fieldnum(VendInvoiceJour, InvoiceDate), fieldnum(VendInvoiceTrans, InvoiceDate));
qbds.addLink(fieldnum(VendInvoiceJour, numberSequenceGroup), fieldnum(VendInvoiceTrans, numberSequenceGroup));
qbds.addLink(fieldnum(VendInvoiceJour, InternalInvoiceId), fieldnum(VendInvoiceTrans, InternalInvoiceId));

qbds = qbds.addDataSource(tableNum(PurchLine));
qbds.relations(false);
qbds.joinMode(joinMode::InnerJoin);
qbds.addLink(fieldnum(VendInvoiceTrans, InventTransId), fieldnum(PurchLine, InventTransId));

qbds = qbds.addDataSource(tableNum(VSN_PURCHORDERJOUR));
qbds.relations(false);
qbds.joinMode(joinMode::InnerJoin);
qbds.addLink(fieldnum(PurchLine, VSN_PURCHORDERID), fieldnum(VSN_PURCHORDERJOUR, ORDERID));
qbds.addRange(fieldnum(VSN_PURCHORDERJOUR, CENTERPROFIX)).value(QueryValue('008-001'));

[ZVV]

Цитата:

Сообщение от Deepoint

qbdsLedgerJoined.addRange(fieldId2Ext(fieldnum(BankAccountTrans, Dimension),1)).value(bankPaymentOrderJourReport_RU.dimension());

Не совсем понял, разобрались тут уже во всём или нет...
но возможно причина просто в том, что ваш параметр аналитики (bankPaymentOrderJourReport_RU.dimension()) - пустой?

Тогда как я понимаю при такой записи рэндж действительно не добавится.
Надо добавить queryValue() видимо...