Query для 3-х таблиц с группировкой.

[user_ax]

Цитата:

Сообщение от maldini

Странно все это. Ещё раз все аккуратно проверь, все должно получится.

Сейчас переписываю по вашему примеру, буду надеяться, что получиться

[user_ax]

Если джойнить 2 таблицы - всё замечательно, когда пытаюсь приджойнить третью - qbds валится в null.

Queryrun main_query(boolean _count_query = false)
{

    Query query   =      new Query();
    QueryBuildDataSource qbds;
   
    ;
    qbds  = query.addDataSource(tablenum(VendInvoiceTrans));
    qbds.addSortField(fieldnum(VendInvoiceTrans,ItemId));
    qbds.addSortField(fieldnum(VendInvoiceTrans,InternalSp));
    qbds.addSelectionField(fieldnum(VendInvoiceTrans,Qty), SelectionField::Sum);
    qbds.orderMode(OrderMode::GroupBy);
    qbds  = qbds.addDataSource(tablenum(VendSpListTrans));
    qbds.addLink(fieldnum(VendSpListTrans,InternalSp),fieldnum(VendInvoiceTrans,InternalSp));
    qbds.joinMode(JoinMode::InnerJoin);
    
    qbds = query.dataSourceTable(tableNum(VendSpListJour));
    qbds.addLink(fieldnum(VendSpListTrans,InternalSp),fieldnum(VendSpListJour,InternalSP));
    qbds.joinMode(JoinMode::InnerJoin);
    
    if (datefromstr && datetostr)
    {
        qbds.addRange(fieldnum(VendSpListJour,SpDate)).value(SysQuery::range(datefrom.value(),dateto.value()));
    }
    if (vendaccountstr)
    {
        qbds.addRange(fieldnum(VendSpListJour,OrderAccount)).value(SysQuery::value(vendaccountstr));
    }
     //если введён регистранионный номер договора
    if (rcontractaccountstr)
    {
        qbds.addRange(fieldnum(VendSpListJour, RcontractAccount)).value(SysQuery::value(rcontractaccount.value()));
    }
    //если введён Владелец
    if (emplidstr)
    {
        qbds.addRange(fieldnum(VendSpListJour, Emplid)).value(SysQuery::value(emplid.value()));
    }
    switch(spclosedstr)
    {
        case (AllOpenPosted::All):
           qbds.addRange(fieldnum(VendSpListJour,SpClosed));
        break;

        case (AllOpenPosted::Open):
           qbds.addRange(fieldnum(VendSpListJour,SpClosed)).value('1');
        break;

        case (AllOpenPosted::Posted):
           qbds.addRange(fieldnum(VendSpListJour,SpClosed)).value('0');
        break;
        default:
        break;
    }
    qbds = query.dataSourceTable(tablenum(VendInvoiceTrans));
    
    if (_count_query)
    {
        qbds.addSelectionField(fieldnum(VendinvoiceTrans,RecId), SelectionField::Count);
    }
    
    qbds = query.dataSourceTable(tablenum(VendSpListTrans));

    return (new QueryRun(query));
   
}

валится на qbds = query.dataSourceTable(tableNum(VendSpListJour));
qbds.addLink(fieldnum(VendSpListTrans,InternalSp),fieldnum(VendSpListJour,InternalSP));

Если заккоментировать весь кусок от qbds = query.dataSourceTable(tableNum(VendSpListJour));
и до конца switch - всё замечательно работает.

Уважаемый maldini, не знаете, в чём причина?

[user_ax]

А, я понял, я не добавляю датасорс, я пытаюсь узнать его id

[user_ax]

Цитата:

Сообщение от maldini

А зачем так много таблиц, ведь данные, если я не ошибаюсь будут только в VendInvoiceTrans

Нет, данные будут из всех таблиц, которые я джойню.

[ice]

если я вас правильно понял, то вам не сделать это одним запросом. делайте while select по двум таблицам, и в цикле группировку по VendInvoiceTrans

[user_ax]

Цитата:

Сообщение от maldini

Для того что бы получить значения полей из других таблиц их надо тоже включать в группировку.

Скажите, пожалуйста, а каким образом их добавить в группировку?

К какому Qbds их цеплять ?

Сейчас опять запрос валится с ошибкой что Источник данных не входит в состав родительского источника данных.

[user_ax]

Цитата:

Сообщение от ice

если я вас правильно понял, то вам не сделать это одним запросом. делайте while select по двум таблицам, и в цикле группировку по VendInvoiceTrans

Почему-то мне кажется, что я тоже не сделаю через query это.

[user_ax]

Уважаемый maldini , если бы там было 3 таблицы, было бы более наглядно, с двумя у меня замечательно выходит и так.

[maldini]

Цитата:

Сообщение от user_ax

Скажите, пожалуйста, а каким образом их добавить в группировку?

К какому Qbds их цеплять ?

Сейчас опять запрос валится с ошибкой что Источник данных не входит в состав родительского источника данных.

While select даст вам тоже самое что и query. Просто нужные поля надо добавить в группировку

qbds  = query.addDataSource(tablenum(VendInvoiceTrans));
    qbds.addSortField(fieldnumVendInvoiceTrans,ItemId));
    qbds.addSortField(fieldnum(VendInvoiceTrans,InternalSp));
    qbds.addSelectionField(fieldnumVendInvoiceTrans,Qty), SelectionField::Sum
    qbds.orderMode(OrderMode::GroupBy);
    qbds  = qbds.addDataSource(tablenum(VendSpListTrans));
    qbds.addLink(fieldnum(VendSpListTrans,InternalSp),fieldnum(VendInvoiceTrans,InternalSp));
qbds.addSortField(fieldnum(VendSpListTrans,InternalSp));
qbds.orderMode(OrderMode::GroupBy);
    qbds.joinMode(JoinMode::InnerJoin);

Вот так и перечислить все что нужно видеть.

[maldini]

Цитата:

Сообщение от user_ax

Уважаемый maldini , если бы там было 3 таблицы, было бы более наглядно, с двумя у меня замечательно выходит и так.

Вот пример из 3 таблиц, так же можно ещё добавить таблицы

void main_query(boolean _count_query = false)
{
    VendInvoiceJour     VendInvoiceJour;
    VendInvoiceTrans    VendInvoiceTrans;
    InventTable         inventTable;
    QueryRun            QueryRun;
    Query query   =      new Query();
    QueryBuildDataSource qbds;
    QueryBuildRange      qbr;
    ;
    qbds  = query.addDataSource(tablenum(VendInvoiceJour));
    qbds.addSortField(fieldnum(VendInvoiceJour,purchId));
    qbds.addSelectionField(fieldnum(VendInvoiceJour,Qty), SelectionField::Sum);
    qbds.orderMode(OrderMode::GroupBy);
    qbds.addRange(fieldnum(VendInvoiceJour,purchId)).value('ЗП-000006');
 
    qbds  = qbds.addDataSource(tablenum(VendInvoiceTrans));
    qbds.addSortField(fieldnum(VendInvoiceTrans,purchId));
    qbds.orderMode(OrderMode::GroupBy);
    qbds.addLink(fieldnum(VendInvoiceJour,purchId),fieldnum(VendInvoiceTrans,purchId));
    qbds  = qbds.addDataSource(tablenum(InventTable));
    qbds.addSortField(fieldnum(InventTable,ItemId));
    qbds.orderMode(OrderMode::GroupBy);
    qbds.addLink(fieldnum(InventTable,ItemId),fieldnum(VendInvoiceTrans,ItemId));
    qbds.relations(true);
 
    QueryRun = new QueryRun(query);
    while (queryRun.next())
    {
        VendInvoiceJour = QueryRun.get(tablenum(VendInvoiceJour));
        VendInvoiceTrans    = QueryRun.get(tablenum(VendInvoiceTrans));
        inventTable         = QueryRun.get(tablenum(InventTable));
        info(strFmt("%1  %2",VendInvoiceJour.PurchId,VendInvoiceJour.Qty));
        info(strFmt("%1",VendInvoiceTrans.PurchId));
        info(strFmt("%1",InventTable.itemId));
    }
}

Если в запросе есть группировка то доступными будут только сгруппированные данные. Так работает любой sql. Выводится только то что присутствует в группировке, например InventTable.ItemGroup будет пустым так как его нет в группировке