AX 2009. Ошибка при отправке письма SysMailer

[SuperStar88]

Добрый день!
Некоторым пользователям не отправляются письма. Выскакивает ошибка:

Неудачная попытка определить вариантный тип параметра 1 для метода "fields". 
Параметр не был правильно инициализирован.\n
\n
Стек вызовов\n
(C)\Classes\COM\fields
(C)\Classes\SysMailerConfiguration\fields - Строка 8
(C)\Classes\SysMailer\new - Строка 27
(C)\Classes\MyClass\sendEmail - Строка 29

В чём может быть дело? Куда копать?

[Pandasama]

Куда копать - я бы поставил точку останова в (C)SysMailerConfiguration на строке 8 и посмотрел, какие параметры в метод fields в COM передаются - на каких работает нормально, а на каких COM выдает ошибку.
Возможно это наведет на какие-то следы того, что что-то не так с параметрами - тогда надо смотреть откуда они берутся и почему такие.

[dech]

Покажите сперва код в MyClass.sendEmail().

[dech]

Мы лично в new() ничего не указываем, вот пример корректного использования.

public void run()
{
    SysMailer           mailer;
    SysEmailParameters  parameters = SysEmailParameters::find();
    ;

    try
    {
        new InteropPermission(InteropKind::ComInterop).assert();

        mailer = new SysMailer();
        mailer.SMTPRelayServer(
            parameters.SMTPRelayServerName ? parameters.SMTPRelayServerName : parameters.SMTPServerIPAddress,
            parameters.SMTPPortNumber,
            parameters.SMTPUserName,
            SysEmailParameters::password(),
            parameters.NTLM
        );
        if (!this.validate())
        {
            throw error("Can't send an email");
        }

        mailer.fromAddress(sender);
        mailer.tos().appendAddress(recipient);
        mailer.priority(1);
        mailer.subject(subject);
        if (htmlBody)
        {
            mailer.htmlBody(htmlBody);
        }
        else if (body)
        {
            mailer.body(body);
        }
        mailer.sendMail();

        CodeAccessPermission::revertAssert();
    }
    catch(Exception::Internal)
    {
        throw Exception::Internal;
    }
}

[БАХ43]

Попробуйте копнуть в сторону SSL шифрования. Вот мой допил SysMailer:

void SMTPRelayServer(str _server, int _port=25, str _userName='',str _password='', boolean _useNTLM=false, boolean _useSSL=true)
{
    ;

    _fields.add(#SmtpServer,_server);
    _fields.add(#SmtpServerPort,_port);
//BAH273 20.11.2018 ->
    if (_useSSL)
    {
        _fields.add(#SmtpUseSSL, 1);
    }
//BAH273 20.11.2018 <-
    if (_useNTLM)
    {
        _fields.add(#SmtpAuthenticate,2);
    }
    else if (_userName)
    {
        //basic authentication
        _fields.add(#SmtpAuthenticate,1);
        _fields.add(#SmtpSendUserName,_userName);
        _fields.add(#SmtpSendUserPassword,_password);
    }

    _fields.resync();

}

и в макросе SysMailer добавить строчку

#define.SmtpUseSSL              ('http://schemas.microsoft.com/cdo/configuration/smtpusessl')

[SuperStar88]

Цитата:

Сообщение от dech

Мы лично в new() ничего не указываем, вот пример корректного использования.

Тоже в new() ничего не указываю, какой-то глюк в обычном функционале

public boolean sendEmail()
{
    #define.Event("Event")

    str                                 liq_message;
    SysMailer                           liq_Mailer;
    SysMailerAddressField               liq_tos;

    SysEmailMessageTable                message;
    SysEmailTable                       emailTable;
    boolean                             liq_mailInitialized;

    Responsibility_ZTR      responsibility;
    SysUserInfo             sysUserInfo;
    SysCompanyUserInfo      sysCompanyUserInfo;

    boolean                 ret = false;

    void liq_initMail()
    {
        SysEmailParameters parameters = SysEmailParameters::find();
        InteropPermission interopPermission;
        ;
        interopPermission = new InteropPermission(InteropKind::ComInterop);
        interopPermission.assert();
        
        liq_Mailer = new SysMailer();
        if(parameters.smtpRelayServerName)
        {
            liq_Mailer.SMTPRelayServer(parameters.smtpRelayServerName,
                parameters.smtpPortNumber,
                parameters.smtpUserName,
                SysEmailParameters::password(),
                parameters.ntlm);
        }
        else
        {
            liq_Mailer.SMTPRelayServer(parameters.smtpServerIPAddress,
                parameters.smtpPortNumber,
                parameters.smtpUserName,
                SysEmailParameters::password(),
                parameters.ntlm);
        }
        liq_mailInitialized = true;
    }
    ;

    subjectMail = this.setSubjectMail();
    liq_message = this.setMessage();

    emailTable = SysEmailTable::find(#Event);
    while select EmplId from responsibility
    {
        select UserId from sysCompanyUserInfo where sysCompanyUserInfo.EmplId == responsibility.EmplId
            join Email from sysUserInfo where sysUserInfo.Id == sysCompanyUserInfo.UserId;

        if(!liq_mailInitialized)
            liq_initMail();

        if (liq_Mailer != null && SysEmailDistributor::validateEmail(sysUserInfo.Email))
        {
            liq_Mailer.fromAddress(emailtable.SenderAddr);
            liq_Mailer.subject(subjectMail);
            liq_tos = liq_Mailer.tos();
            liq_tos.clear();
            liq_Mailer.tos().appendAddress(sysUserInfo.Email);
            liq_Mailer.priority(1);
            liq_Mailer.htmlBody(liq_message);
            liq_Mailer.sendMail();

            ret = true;
        }
    }
    return ret;
}

[БАХ43]

Еще одно предположение. sysUserInfo.Email - 255 символов, а расширенный тип данных Email - 80 символов. Может где-то адрес обрезается и становится неверным. У меня такое было, когда у пользователя несколько адресов, общей длинной больше 80 символов. Правда не помню какую ошибку давало.