Field Groups

[ZhanR]

Добрый день!
Подскажите плиз как узнать из кучи групп полей в наличии (например в empltable), найти в какие группы входит интересующее меня поле? имеется в виду помимо визуального поиска.

[Sada]

Цитата:

Сообщение от ZhanR

Добрый день!
Подскажите плиз как узнать из кучи групп полей в наличии (например в empltable), найти в какие группы входит интересующее меня поле? имеется в виду помимо визуального поиска.

Выберите правку дизайна формы, найдите ваше поле, выберите группу этого поля, откройте свойства - свойство DataGroup.

[Dron AKA andy]

Используйте перекрестные ссылки по полю.

[Gustav]

AOT \ System Documentation \ Classes \ DictTable
AOT \ System Documentation \ Classes \ DictField
AOT \ System Documentation \ Classes \ DictFieldGroup

пример их хелпа к методу DictFieldGroup.numberOfFields:

DictFieldGroup t = new DictFieldGroup(_tableId, _fieldGroupName);
DictField f;
int i;
fieldId id;
;
if (t)
{
    for (i=1; i<=t.numberOfFields(); i++)  // numbering starts at 1
    {
        id = t.field(i);
        f  = new DictField(dict.tableName2Id(_tableName), id);
        if (f) print 'Field: ' + f.name() + ' (' + int2str(id) + ')';    
        else  print 'MethodName: ' + t.methodName(id) + ' (' + int2str(id) + ')';
    }
}

[oip]

static void JOB6666()
{
    SysDictTable       dictTable;
    SysDictField       dictField;
    DictFieldGroup     dictGroup;
    int                i,j;

    #define.tableName('EmplTable')
    #define.fieldName('Name')
    ;

    dictTable = new SysDictTable(tableName2Id(#tableName));
    if (dictTable)
    {
        for (i = 1; i<= dictTable.fieldGroupCnt();i++)
        {
            dictGroup = new DictFieldGroup(tableName2Id(#tableName), dictTable.fieldGroup(i));
            if (dictGroup)
            {
                for(j=1;j<=dictGroup.numberOfFields();j++)
                {
                    if (dictGroup.field(j) == fieldname2id(tableName2Id(#tableName), #fieldName))
                        info (dictGroup.name());
                }
            }
        }
    }
    else
    {
        error ('Такой таблицы нет!');
    }
}

Uptade: Пока писал - опередили.

[Gustav]

Цитата:

Сообщение от oip

Пока писал - опередили.

Не опередили, не опередили. Я лишь съобезъянничал с копипастом, а это дело нехитрое.
У Вас же - гораздо более ценная ручная работа!

[ZhanR]

Спасибо большое!