fieldnum и map custVendTrans - как получить идентификатор поля таблицы по мапу?

[mazzy]

Дурной вопрос. Понял, что я не знаю красивого ответа. Может подскажете?

Есть:
= код, в котором объявлена переменная типа map CustVendTrans
= запрос, который содержит либо custTrans, либо vendTrans в зависимости от внешних
= метод, который устанавливает range в этом запросе
= для range нужно получить fieldnum

вопрос:
а как проще и красивше получить fieldnum?

    CustVendTrans           custVendTrans           = custVendTransStatic.custVendTrans();
    Query                   q;
    QueryBuildDataSource    qbds;
;
    switch( _journalTable.JournalModule)
    {
        case ModuleCustVend::Cust:
            q = new Query(querystr(myCustQuery));
            break;
        case ModuleCustVend::Vend:
            q = new Query(querystr(myVendQuery));
            break;
        default:
            throw Error::unsupportedEnumValue(_journalTable.JournalModule);
    }

    qbds = q.dataSourceTable(custVendTrans.TableId);

    // здесь возвращает fieldid из мапа = 39, а нужно для CustTrans = 41, а для VendTrans = 78
    SysQuery::findOrCreateRange(qbds, fieldnum(custVendTrans, ExchRate)       ).value(myValue);

    // есть еще много критериев. как бы красиво оформить?
    SysQuery::findOrCreateRange(qbds, fieldnum(custVendTrans, ....
    SysQuery::findOrCreateRange(qbds, fieldnum(custVendTrans, ....
    SysQuery::findOrCreateRange(qbds, fieldnum(custVendTrans, ....
    SysQuery::findOrCreateRange(qbds, fieldnum(custVendTrans, ....

понятно, что можно вставить в switch. но тогда код будет дублироваться. некрасиво. хотя везде в стандартной аксапте именно так и делается

понятно, что можно через DictField, но получается слишком длинный код, когда критериев (range) достаточно много.

есть еще какой-нибудь способ?

[Dron AKA andy]

MappingsInfo_RU::createMapWithFieldId(), и далее по мапу получать id по названию поля. Правда, способ не очень производительный по времени.

[gl00mie]

Нужно быть очень аккуратным при работе с классом MappingsInfo_RU в AX 2009: метод findMappingTreeNode() в этой версии использует вызов infolog.getNode(), который сам выполняется и возвращает объект на клиенте. Затем по TreeNode'у в методе find() бегает TreeNodeIterator, который в общем случае может создаваться на сервере (если сам класс используется на сервере). В итоге можно словить труднодиагностируемые тормоза и нефиговый клиент-серверный трафик в чисто серверном, как может показаться, коде. В 2012-й реализацию findMappingTreeNode() с этой точки зрения исправили.
В данном конкретном случае я бы лично, возможно, заложился на то, что названия используемых в запросе полей в CustTrans, VendTrans и CustVendTrans совпадают, и использовал бы конструкцию вида

fieldId = fieldName2Id(tableId, fieldStr(CustVendTrans, ExchRate));

[mazzy]

Цитата:

Сообщение от gl00mie

В данном конкретном случае я бы лично, возможно, заложился на то, что названия используемых в запросе полей в CustTrans, VendTrans и CustVendTrans совпадают, и использовал бы конструкцию вида

fieldId = fieldName2Id(tableId, fieldStr(CustVendTrans, ExchRate));

не-а.
здесь есть кастомные поля. с разными названиями.

а без имен в стандарте можно?

[gl00mie]

Если имена полей отличаются, то из решений, лежащих на поверхности, - либо MappingsInfo_RU, либо иерархия классов с методами вида fieldId transFieldExchRate(), где наследники для нужной таблицы возвращают именно ее fieldId, по аналогии с RLedgerSheetEngine. Хотя по-моему, последнее - это overengineering для данной постановки задачи.

[raz]

Можно попробовать пойти таким путем.

protected FieldId fieldIdByExtendedType(TableId _tableId, int _extendedTypeNum)
{
    DictTable       dictTable = new DictTable(_tableId);
    DictField       dictField;

    ExtendedTypeId  extendedTypeId;
    FieldId         fieldId, fieldIdRet;
    int             i, n;
    ;

    fieldId = dictTable.fieldNext(0);

    while (fieldId && ! isSysId(FieldId))
    {
        dictField      = new DictField(DictTable.id(), fieldId);
        extendedTypeId = dictField.typeId();

        if (extendedTypeId == _extendedTypeNum)
        {
            fieldIdRet = fieldId;
            break;
        }

        fieldId        = dictTable.fieldNext(fieldId);
    }

    return fieldIdRet;
}

[mazzy]

Цитата:

Сообщение от gl00mie

Хотя по-моему, последнее - это overengineering для данной постановки задачи.

угу.

Цитата:

Сообщение от raz

Можно попробовать пойти таким путем.

спасибо.

делаю предварительный вывод:
1. в стандарте из готовых методов только MappingsInfo_RU (но он работает медленно по именам)
2. делать свой служебный класс.
3. не выпендриваться, засунуть в switch-case ))

я думал, что забыл что-нибудь.
ок. спасибо.

[AndyD]

Есть еще такой вариант Некорректное отражение map при пакетной обработке в Ax2009, и налоги в строках накладных/фактур

[mazzy]

оооо, на том проекте, где я сейчас, уже создали служебные классы...

в двух словах:
- сначала парсится node-ветка mapping из map-объекта-AOT,
- значения складываются в map-класс
- потом используется.

причем уже есть синглтон, все дела... гут. буду юзать.

еще раз всем спасибо.

[michel1971]

если 12-ка, то можно вот так

public static FieldId getMappedField(TableId   _mapId,
                                     TableId   _mappedTableId,
                                     FieldId   _mapFieldId)
{
    FieldId             ret;
    DictTable           dictTable;
    DictTableMap        dictTableMap;
    int                 i;

    if (_mapId && _mapFieldId && _mappedTableId)
    {
        dictTable = new DictTable(_mapId);
        if (dictTable && dictTable.isMap())
        {
            for (i = dictTable.mapCnt(); i >= 1; i--)
            {
                dictTableMap = dictTable.mapObject(i);
                if (dictTableMap.table() == _mappedTableId)
                {
                    break;
                }
                dictTableMap = null;
            }

            if (dictTableMap)
            {
                for (i = dictTableMap.fieldCnt(); i >= 1; i--)
                {
                    if (dictTableMap.fieldCnt2FieldFrom(i) == _mapFieldId)
                    {
                        ret = dictTableMap.fieldCnt2FieldTo(i);
                        break;
                    }
                }
            }
        }
    }

    return ret;
}

[DSPIC]

До кучи готовый стандартный класс с поддержкей кеширования.

\Classes\VendDocumentUtil
Вложение 9369