Как привязать две таблицы или как это наз-ся?

[I don't understand]

В общем я хочу чтобы строки одной таблицы расшифровывали строку другой таблицы. Только я хочу это сделать не через EDT и установку linktype, а с помощью кода. Помогите, расскажите или скиньте примерчик. СПАСИБО

[Prof]

вопрос в общем-то непонятен

[Sirius]

Вот посмотри.. В этом методе создается связь.

PHP код:

public void lookup()
{
    SysTableLookup        sysTableLookup = SysTableLookup::newParameters(tableNum(InventTable), this);
    Query                 q;
    QueryBuildDataSource  qbd1;
    QueryBuildDataSource  qbd2;

    QueryBuildRange       qbr;

    ;
    q = new Query();
    qbd1 = q.addDataSource(tableNum(InventTable));

    qbd2 = qbd1.addDataSource(tableNum(WMSOrderTrans));

    qbr = qbd2.addRange(fieldnum(WMSOrderTrans, routeId));
    
    qbd2.joinMode(JoinMode::ExistsJoin);
    qbd2.addLink(fieldnum(InventTable, itemId), fieldnum(WMSOrderTrans,itemId));

    sysTableLookup.addLookupfield(fieldNum(InventTable, itemId));
    sysTableLookup.addLookupfield(fieldNum(InventTable, itemName));
    sysTableLookup.parmQuery(q);
    sysTableLookup.performFormLookup();
} 


[I don't understand]

А где данная процедура должна быть повешена (прописана) для обработки ее программой

[Sirius]

я думаю если вы именно этот метод куда-нибудь вставите и запустите, это вам не очень поможет.

здесь просто показано как создать query который будет брать данные из двух связанных таблиц.

возьмите две ваши таблицы и создайте query по этому примеру

[I don't understand]

Я создам query по вашему примеру (жаль что без комментариев) а потом как сделать чтобы все подцепилось ?? Вот это мне не понятно, я программлю на Аксапте всего пол-месяца , так что извините , если вопрос поставлен странно (тупо, глупо и т.д.)

[Sirius]

Хм. Что значит чтобы все подцепилось?

Ладно давайте по шагам.

Создаем две таблицы.

TestMain из одного поля: id
TestDetails из двух полей: id и details

вписываем туда данные и создаем вот такой job:

PHP код:

static void DynamicJoin(Args _args)
{
    Query                 q;
    QueryRun              qr;
    QueryBuildDataSource  qbd1;
    QueryBuildDataSource  qbd2;
    QueryBuildRange       qbr;

    TestMain    tm;
    TestDetails td;


    ;

    q = new Query();

     //добавляем основной datasource
    qbd1 = q.addDataSource(tableNum(TestMain));

    //добавляем datasource, который будем связывать с основным
    qbd2 = qbd1.addDataSource(tableNum(TestDetails));


    //устанавливаем тип связи
    qbd2.joinMode(JoinMode::InnerJoin);
    //устанавливаем саму связь
    qbd2.addLink(fieldnum(TestMain, ID), fieldnum(TestDetails,ID));

    qr = new QueryRun(q);
    while(qr.next())
    {
        //получаем данные
        tm = qr.get(tablenum(TestMain));
        td = qr.get(tablenum(TestDetails));

        //смотрим что получили
        info(tm.ID+" "+td.Details);
    }


} 


Вот. Может вам что другое надо. Но вы тогда объясните поподробнее, чтобы народ не гадал что же вы все таки хотите

[Владимир Максимов]

Ты опиши что именно хочешь увидеть в результате. Не в смысле кода, а какую картинку на форме.

Дело в том, что AXAPTA - это не есть язык программирования. В ней заложена возможность написания кода, но это не приветствуется! Общая идея AXAPTA - если что-то может быть сделано визуально именно так это и надо делать. Кодить надо только в том случае, если визуально поставленную задачу решить не удалось.

[I don't understand]

Владимир Максимов - спасибо за совет, вот только где вы видели хороших программистов, которые не пишут не строчки кода ? Хотя конечно если есть уже что-то написанное и , что самое главное, отлаженное - зачем городить огород... Я же сейчас познаю азы.

Спасибо Sirius, только еще один маааленький question : мы создали job, а пользователь открывать будет форму с нашими 2-мя таблицами, и как этот job будет взаим-ть с ними ( таблицами )? или его нужно указать в качестве свойства одной из таблиц ???????

[Sirius]

эээ нет..

если вы хотите чтобы это все работало в гриде на форме, то действовать нужно немного по другому.

смотрите в прикрепленном проекте.

вкратце. переопределяем метод executeQuery() основного датасорса, где меняем ему query.

[mazzy]

Цитата:

Изначально опубликовано I don't understand
Владимир Максимов - спасибо за совет, вот только где вы видели хороших программистов, которые не пишут не строчки кода ?

Где вы видели хороших программистов, которые смотрят в мануалы и туториалы?
Поглядите в формы, названия которых начинаютя с tutorial_ .
Вам, как хорошим программистам будет полезно.

[I don't understand]

to mazzy Хорош подкалывать, написал же пол - месяца всего с Axapta связан, только курсы по программированию закончил, впереди еще по Финансам и Логистике...........

Sirius СПАСИБО я все понял !!!!! Скинь свой адрес, я тебе бандеролью пиво вышлю

[mazzy]

хорошо. тогда только совет: посмотрите формы, названия которых начинаются с tutorial_. Там много полезного

[Sirius]

Цитата:

Изначально опубликовано I don't understand
Sirius СПАСИБО я все понял !!!!!

да не за что мне здесь помогали (за что всем спасибо большое ) - теперь и я помогаю чем могу

Цитата:

Скинь свой адрес, я тебе бандеролью пиво вышлю